[E-Documents Core] - Manual multiple files import

Apps/W1/EDocument/app/src/Document/EDocuments.Page.al

@@ -65,12 +65,29 @@ page 6122 "E-Documents"
                 Caption = 'New From File';
                 ToolTip = 'Create an electronic document by manually uploading a file.';
                 Image = Import;
+                Visible = false;
 
                 trigger OnAction()
                 begin
                     NewFromFile();
                 end;
             }
+            fileuploadaction(ImportManuallyMultiple)
+            {
+                Caption = 'Import Files';
+                ToolTip = 'Create electronic documents by uploading single or multiple files.';
+                Image = Import;
+                AllowedFileExtensions = '.xml';
+                AllowMultipleFiles = true;
+                trigger OnAction(Files: List of [FileUpload])
+                var
+                    EDocImport: Codeunit "E-Doc. Import";
+                begin
+                    EDocImport.UploadDocuments(Files);
+                    CurrPage.Update();
+                end;
+
+            }
             action(EDocumentServices)
             {
                 RunObject = Page "E-Document Services";
@@ -88,7 +105,8 @@ page 6122 "E-Documents"
         }
         area(Promoted)
         {
-            actionref(Promoted_ImportManually; ImportManually) { }
+            actionref(Promoted_ImportManually; ImportManually) { Visible = false; }
+            actionref(Promoted_ImportManuallyMultiple; ImportManuallyMultiple) { }
             actionref(Promoted_EDocumentServices; EDocumentServices) { }
         }
     }

Apps/W1/EDocument/app/src/Integration/EDocIntegrationManagement.Codeunit.al

@@ -198,6 +198,7 @@ codeunit 6134 "E-Doc. Integration Management"
     local procedure ReceiveSingleDocument(var EDocument: Record "E-Document"; var EDocumentService: Record "E-Document Service"; DocumentMetadata: Codeunit "Temp Blob"; IDocumentReceiver: Interface IDocumentReceiver): Boolean
     var
         ReceiveContext, FetchContextImpl : Codeunit ReceiveContext;
+        EDocumentContent: Codeunit "Temp Blob";
         ErrorCount: Integer;
         Success, IsFetchableType : Boolean;
     begin
@@ -209,19 +210,22 @@ codeunit 6134 "E-Doc. Integration Management"
         if not Success then
             exit(false);
 
-        if not ReceiveContext.GetTempBlob().HasValue() then
+        EDocumentContent := ReceiveContext.GetTempBlob();
+        if not EDocumentContent.HasValue() then
             exit(false);
 
         IsFetchableType := IDocumentReceiver is IReceivedDocumentMarker;
         if IsFetchableType then begin
             ErrorCount := EDocumentErrorHelper.ErrorMessageCount(EDocument);
             RunMarkFetched(EDocument, EDocumentService, ReceiveContext.GetTempBlob(), IDocumentReceiver, FetchContextImpl);
             Success := EDocumentErrorHelper.ErrorMessageCount(EDocument) = ErrorCount;
-
             if not Success then
                 exit(false);
         end;
 
+        if HasDuplicate(EDocument, EDocumentContent, EDocumentService."Document Format") then
+            exit(false);
+
         // Only after sucecssfully downloading and (optionally) marking as fetched, the document is considered imported
         // Insert logs for downloading document
         InsertLogAndEDocumentStatus(EDocument, EDocumentService, ReceiveContext.GetTempBlob(), ReceiveContext.Status().GetStatus());
@@ -235,6 +239,24 @@ codeunit 6134 "E-Doc. Integration Management"
     end;
 
 
+    internal procedure HasDuplicate(var IncomingEDocument: Record "E-Document"; var EDocumentContent: Codeunit "Temp Blob"; IEDocument: Interface "E-Document"): Boolean
+    var
+        EDocument: Record "E-Document";
+        EDocGetBasicInfo: Codeunit "E-Doc. Get Basic Info";
+    begin
+        // Commit before getting basic info with error handling (if Codeunit.Run then )
+        Commit();
+        EDocGetBasicInfo.SetValues(IEDocument, IncomingEDocument, EDocumentContent);
+        if not EDocGetBasicInfo.Run() then
+            exit(false);
+        EDocGetBasicInfo.GetValues(IEDocument, IncomingEDocument, EDocumentContent);
+
+        EDocument.SetFilter("Entry No", '<>%1', IncomingEDocument."Entry No");
+        EDocument.SetRange("Incoming E-Document No.", IncomingEDocument."Incoming E-Document No.");
+        EDocument.SetRange("Bill-to/Pay-to No.", IncomingEDocument."Bill-to/Pay-to No.");
+        EDocument.SetRange("Document Date", IncomingEDocument."Document Date");
+        exit(not EDocument.IsEmpty());
+    end;
     #endregion
 
     #region Actions
@@ -564,7 +586,6 @@ codeunit 6134 "E-Doc. Integration Management"
         exit(true);
     end;
 
-
     #endregion
 
     var

Apps/W1/EDocument/app/src/Processing/EDocImport.Codeunit.al

@@ -4,6 +4,7 @@
 // ------------------------------------------------------------------------------------------------
 namespace Microsoft.eServices.EDocument;
 
+using Microsoft.eServices.EDocument;
 using Microsoft.Finance.GeneralLedger.Journal;
 using Microsoft.Purchases.Vendor;
 using Microsoft.Purchases.Document;
@@ -19,33 +20,38 @@ codeunit 6140 "E-Doc. Import"
     internal procedure UploadDocument(var EDocument: Record "E-Document")
     var
         EDocumentService: Record "E-Document Service";
-        TempBlob: Codeunit "Temp Blob";
-        OutStr: OutStream;
         InStr: InStream;
         FileName: Text;
     begin
-        if Page.RunModal(Page::"E-Document Services", EDocumentService) <> Action::LookupOK then
+        if not this.ChooseEDocumentService(EDocumentService) then
             exit;
 
         if not UploadIntoStream('', '', '', FileName, InStr) then
             exit;
 
-        TempBlob.CreateOutStream(OutStr);
-        CopyStream(OutStr, InStr);
+        this.ImportEDocumentFromStream(EDocument, EDocumentService, InStr);
+    end;
 
-        EDocument.Direction := EDocument.Direction::Incoming;
-        EDocument."Document Type" := Enum::"E-Document Type"::None;
+    internal procedure UploadDocument(var EDocument: Record "E-Document"; EDocumentService: Record "E-Document Service"; DocumentFile: FileUpload): Boolean
+    var
+        DocumentInStream: InStream;
+    begin
+        DocumentFile.CreateInStream(DocumentInStream);
+        exit(this.ImportEDocumentFromStream(EDocument, EDocumentService, DocumentInStream));
+    end;
 
-        if EDocument."Entry No" = 0 then begin
-            EDocument.Insert(true);
-            EDocumentProcessing.InsertServiceStatus(EDocument, EDocumentService, Enum::"E-Document Service Status"::Imported);
-        end else begin
-            EDocument.Modify(true);
-            EDocumentProcessing.ModifyServiceStatus(EDocument, EDocumentService, Enum::"E-Document Service Status"::Imported);
-        end;
+    internal procedure UploadDocuments(Documents: List of [FileUpload])
+    var
+        EDocument: Record "E-Document";
+        EDocumentService: Record "E-Document Service";
+    begin
+        if Documents.Count = 0 then
+            exit;
 
-        EDocumentLog.InsertLog(EDocument, EDocumentService, TempBlob, Enum::"E-Document Service Status"::Imported);
-        EDocumentProcessing.ModifyEDocumentStatus(EDocument, Enum::"E-Document Service Status"::Imported);
+        if not this.ChooseEDocumentService(EDocumentService) then
+            exit;
+
+        this.HandleMultipleDocumentUpload(Documents, EDocument, EDocumentService);
     end;
 
     internal procedure GetBasicInfo(var EDocument: Record "E-Document")
@@ -303,7 +309,8 @@ codeunit 6140 "E-Doc. Import"
         UpdateEDocumentRecordId(EDocument, EDocument."Document Type", DocNo, RecordId);
     end;
 
-    local procedure UpdateEDocumentRecordId(var EDocument: Record "E-Document"; EDocType: enum "E-Document Type"; DocNo: Code[20]; RecordId: RecordId)
+    local procedure UpdateEDocumentRecordId(var EDocument: Record "E-Document"; EDocType: enum "E-Document Type"; DocNo: Code[20];
+                                                                                              RecordId: RecordId)
     begin
         EDocument."Document Type" := EDocType;
         EDocument."Document No." := DocNo;
@@ -620,6 +627,39 @@ codeunit 6140 "E-Doc. Import"
             until TempEDocImportedLine.Next() = 0;
     end;
 
+    local procedure ChooseEDocumentService(var EDocumentService: Record "E-Document Service"): Boolean
+    begin
+        exit(not (Page.RunModal(Page::"E-Document Services", EDocumentService) <> Action::LookupOK));
+    end;
+
+    local procedure ImportEDocumentFromStream(var EDocument: Record "E-Document"; EDocumentService: Record "E-Document Service"; var InStr: InStream): Boolean
+    var
+        IntegrationManagement: Codeunit "E-Doc. Integration Management";
+        TempBlob: Codeunit "Temp Blob";
+        OutStr: OutStream;
+    begin
+        TempBlob.CreateOutStream(OutStr);
+        CopyStream(OutStr, InStr);
+
+        EDocument.Direction := EDocument.Direction::Incoming;
+        EDocument."Document Type" := Enum::"E-Document Type"::None;
+
+        if IntegrationManagement.HasDuplicate(EDocument, TempBlob, EDocumentService."Document Format") then
+            exit(false);
+
+        if EDocument."Entry No" = 0 then begin
+            EDocument.Insert(true);
+            EDocumentProcessing.InsertServiceStatus(EDocument, EDocumentService, Enum::"E-Document Service Status"::Imported);
+        end else begin
+            EDocument.Modify(true);
+            EDocumentProcessing.ModifyServiceStatus(EDocument, EDocumentService, Enum::"E-Document Service Status"::Imported);
+        end;
+
+        EDocumentLog.InsertLog(EDocument, EDocumentService, TempBlob, Enum::"E-Document Service Status"::Imported);
+        EDocumentProcessing.ModifyEDocumentStatus(EDocument, Enum::"E-Document Service Status"::Imported);
+        exit(true);
+    end;
+
     internal procedure SetHideDialogs(Hide: Boolean)
     begin
         HideDialogs := Hide;
@@ -637,6 +677,70 @@ codeunit 6140 "E-Doc. Import"
     end;
 #endif
 
+    local procedure HandleMultipleDocumentUpload(var Documents: List of [FileUpload]; var EDocument: Record "E-Document"; EDocumentService: Record "E-Document Service")
+    var
+        Document: FileUpload;
+        DocumentInstream: InStream;
+        MultipleDocuments: Boolean;
+        DuplicateExists: Boolean;
+        NotProcessedDocuments: Integer;
+    begin
+        if Documents.Count > 1 then begin
+            MultipleDocuments := true;
+            this.SetHideDialogs(true);
+        end;
+
+        foreach Document in Documents do begin
+            Clear(EDocument);
+            Clear(DocumentInstream);
+            Document.CreateInStream(DocumentInstream);
+
+            CreateEDocumentFromStream(
+                EDocument,
+                EDocumentService,
+                DocumentInstream,
+                MultipleDocuments,
+                DuplicateExists,
+                NotProcessedDocuments);
+        end;
+
+        if MultipleDocuments then
+            if DuplicateExists then
+                Message(StrSubstNo(DuplicatesMsg, NotProcessedDocuments, Documents.Count()))
+            else
+                Message(DocsImportedMsg);
+    end;
+
+    internal procedure CreateEDocumentFromStream(
+        var EDocument: Record "E-Document";
+        EDocumentService: Record "E-Document Service";
+        var DocumentInstream: InStream;
+        MultipleDocuments: Boolean;
+        var DuplicateExists: Boolean;
+        var NotProcessedDocuments: Integer)
+    begin
+        if not this.ImportEDocumentFromStream(EDocument, EDocumentService, DocumentInstream) then
+            if MultipleDocuments then begin
+                DuplicateExists := true;
+                NotProcessedDocuments += 1;
+            end else
+                Error(
+                    EDocumentAlreadyExistErr,
+                    EDocument.FieldCaption("Incoming E-Document No."),
+                    EDocument."Incoming E-Document No.",
+                    EDocument.FieldCaption("Bill-to/Pay-to No."),
+                    EDocument."Bill-to/Pay-to No.",
+                    EDocument.FieldCaption("Document Date"),
+                    EDocument."Document Date");
+
+        if EDocument."Entry No" <> 0 then begin
+            this.ProcessDocument(EDocument, false);
+            if not this.HideDialogs and EDocErrorHelper.HasErrors(EDocument) then
+                if Confirm(DocNotCreatedQst, true, EDocument."Document Type") then
+                    Page.Run(Page::"E-Document", EDocument);
+        end;
+    end;
+
     var
         EDocumentLog: Codeunit "E-Document Log";
         EDocImportHelper: Codeunit "E-Document Import Helper";
@@ -651,6 +755,10 @@ codeunit 6140 "E-Doc. Import"
         DocTypeIsNotSupportedErr: Label 'Document type %1 is not supported.', Comment = '%1 - Document Type';
         FailedToFindVendorErr: Label 'No vendor is set for Edocument';
         CannotProcessEDocumentMsg: Label 'Cannot process E-Document %1 with Purchase Order %2 before Purchase Order has been matched and posted for E-Document %3.', Comment = '%1 - E-Document entry no, %2 - Purchase Order number, %3 - EDocument entry no.';
+        DocNotCreatedQst: Label 'Failed to create new %1 from E-Document. Do you want to open E-Document and see the reported errors?', Comment = '%1 - E-Document Document Type';
+        EDocumentAlreadyExistErr: Label 'E-Document with %1 %2, %3 %4 and %5 %6 already exists.', Comment = '%1 - Incoming E-Document No. fieldcaption, %2 - Incoming E-Document No. value, %3 - Bill-to/Pay-to No. fieldcaption, %4 - Bill-to/Pay-to No. value, %5 - Document Date fieldcaption, %6 - Document Date value.';
+        DuplicatesMsg: Label '%1 of %2 uploaded documents were not imported because they already exist in the system.', Comment = '%1 - Not processed documents, %2 - Total documents';
+        DocsImportedMsg: Label 'Document(s) imported successfully.';
 
     [IntegrationEvent(false, false)]
     local procedure OnAfterProcessImportedDocument(var EDocument: Record "E-Document"; var DocumentHeader: RecordRef)

Apps/W1/EDocument/edocument_workspace.code-workspace

@@ -0,0 +1,24 @@
+{
+	"settings": {
+		"al.enableCodeAnalysis": true,
+		"al.codeAnalyzers": [
+			"${CodeCop}",
+			"${UICop}",
+			"${AppSourceCop}"
+		]
+	},
+	"folders": [
+		{
+			"name": "app",
+			"path": "app"
+		},
+		{
+			"name": "test",
+			"path": "test"
+		},
+		{
+			"name": "demo data",
+			"path": "demo data"
+		}
+	]
+}