Azure Document Intelligence Module

src/System Application/App/AI/app.json

@@ -90,7 +90,7 @@
   "idRanges": [
     {
       "from": 7758,
-      "to": 7778
+      "to": 7780
     }
   ],
   "target": "OnPrem",

src/System Application/App/AI/src/Azure AI Document Intelligence/ADIModelType.Enum.al

@@ -0,0 +1,29 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace System.AI.DocumentIntelligence;
+
+/// <summary>
+/// The supported model types for Azure OpenAI.
+/// </summary>
+enum 7779 "ADI Model Type"
+{
+    Access = Public;
+    Extensible = false;
+
+    /// <summary>
+    /// Invoice model type.
+    /// </summary>
+    value(0; Invoice)
+    {
+    }
+
+    /// <summary>
+    /// Receipt model type.
+    /// </summary>
+    value(1; Receipt)
+    {
+    }
+
+}

src/System Application/App/AI/src/Azure AI Document Intelligence/AzureDIImpl.Codeunit.al

@@ -0,0 +1,145 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace System.AI.DocumentIntelligence;
+
+using System.Privacy;
+using System.Telemetry;
+using System;
+using System.AI;
+
+/// <summary>
+/// Azure Document Intelligence implementation.
+/// </summary>
+codeunit 7779 "Azure DI Impl."
+{
+    Access = Internal;
+    InherentEntitlements = X;
+    InherentPermissions = X;
+
+    var
+        CopilotCapabilityImpl: Codeunit "Copilot Capability Impl";
+        FeatureTelemetry: Codeunit "Feature Telemetry";
+        AzureDocumentIntelligenceCapabilityTok: Label 'ADI', Locked = true;
+        TelemetryAnalyzeInvoiceFailureLbl: Label 'Analyze invoice failed.', Locked = true;
+        TelemetryAnalyzeInvoiceCompletedLbl: Label 'Analyze invoice completed.', Locked = true;
+        TelemetryAnalyzeReceiptFailureLbl: Label 'Analyze receipt failed.', Locked = true;
+        TelemetryAnalyzeReceiptCompletedLbl: Label 'Analyze receipt completed.', Locked = true;
+        GenerateRequestFailedErr: Label 'The request did not return a success status code.';
+        AzureAiDocumentIntelligenceTxt: Label 'Azure AI Document Intelligence', Locked = true;
+
+
+    procedure SetCopilotCapability(Capability: Enum "Copilot Capability"; CallerModuleInfo: ModuleInfo; AzureAIServiceName: Text)
+    begin
+        CopilotCapabilityImpl.SetCopilotCapability(Capability, CallerModuleInfo, AzureAIServiceName);
+    end;
+
+    /// <summary>
+    /// Analyze a single invoice.
+    /// </summary>
+    /// <param name="Base64Data">Data to analyze.</param>
+    /// <param name="CallerModuleInfo">The module info of the caller.</param>
+    /// <returns>The analyzed result.</returns>
+    procedure AnalyzeInvoice(Base64Data: Text; CallerModuleInfo: ModuleInfo) Result: Text
+    var
+        CustomDimensions: Dictionary of [Text, Text];
+    begin
+        CopilotCapabilityImpl.CheckCapabilitySet();
+        CopilotCapabilityImpl.CheckEnabled(CallerModuleInfo, Enum::"Azure AI Service Type"::"Azure Document Intelligence");
+        CopilotCapabilityImpl.AddTelemetryCustomDimensions(CustomDimensions, CallerModuleInfo);
+
+        if not SendRequest(Base64Data, Enum::"ADI Model Type"::Invoice, CallerModuleInfo, Result) then begin
+            FeatureTelemetry.LogError('0000OLK', AzureDocumentIntelligenceCapabilityTok, TelemetryAnalyzeInvoiceFailureLbl, GetLastErrorText(), '', Enum::"AL Telemetry Scope"::All, CustomDimensions);
+            exit;
+        end;
+
+        FeatureTelemetry.LogUsage('0000OLM', AzureDocumentIntelligenceCapabilityTok, TelemetryAnalyzeInvoiceCompletedLbl, Enum::"AL Telemetry Scope"::All, CustomDimensions);
+
+    end;
+
+    /// <summary>
+    /// Analyze a single receipt.
+    /// </summary>
+    /// <param name="Base64Data">Data to analyze.</param>
+    /// <param name="CallerModuleInfo">The module info of the caller.</param>
+    /// <returns>The analyzed result.</returns>
+    procedure AnalyzeReceipt(Base64Data: Text; CallerModuleInfo: ModuleInfo) Result: Text
+    var
+        CustomDimensions: Dictionary of [Text, Text];
+    begin
+        CopilotCapabilityImpl.CheckCapabilitySet();
+        CopilotCapabilityImpl.CheckEnabled(CallerModuleInfo, Enum::"Azure AI Service Type"::"Azure Document Intelligence");
+        CopilotCapabilityImpl.AddTelemetryCustomDimensions(CustomDimensions, CallerModuleInfo);
+
+        if not SendRequest(Base64Data, Enum::"ADI Model Type"::Receipt, CallerModuleInfo, Result) then begin
+            FeatureTelemetry.LogError('0000OLL', AzureDocumentIntelligenceCapabilityTok, TelemetryAnalyzeReceiptFailureLbl, GetLastErrorText(), '', Enum::"AL Telemetry Scope"::All, CustomDimensions);
+            exit;
+        end;
+
+        FeatureTelemetry.LogUsage('0000OLN', AzureDocumentIntelligenceCapabilityTok, TelemetryAnalyzeReceiptCompletedLbl, Enum::"AL Telemetry Scope"::All, CustomDimensions);
+    end;
+
+    [TryFunction]
+    [NonDebuggable]
+    local procedure SendRequest(Base64Data: Text; ModelType: Enum "ADI Model Type"; CallerModuleInfo: ModuleInfo; var Result: Text)
+    var
+        ALCopilotFunctions: DotNet ALCopilotFunctions;
+        ALCopilotCapability: DotNet ALCopilotCapability;
+        ALCopilotResponse: DotNet ALCopilotOperationResponse;
+        ErrorMsg: Text;
+    begin
+        ClearLastError();
+        ALCopilotCapability := ALCopilotCapability.ALCopilotCapability(CallerModuleInfo.Publisher(), CallerModuleInfo.Id(), Format(CallerModuleInfo.AppVersion()), AzureDocumentIntelligenceCapabilityTok);
+        case ModelType of
+            Enum::"ADI Model Type"::Invoice:
+                ALCopilotResponse := ALCopilotFunctions.GenerateInvoiceIntelligence(GenerateJsonForSingleInput(Base64Data), ALCopilotCapability);
+            Enum::"ADI Model Type"::Receipt:
+                ALCopilotResponse := ALCopilotFunctions.GenerateReceiptIntelligence(GenerateJsonForSingleInput(Base64Data), ALCopilotCapability);
+        end;
+        ErrorMsg := ALCopilotResponse.ErrorText();
+        if ErrorMsg <> '' then
+            Error(ErrorMsg);
+
+        if not ALCopilotResponse.IsSuccess() then
+            Error(GenerateRequestFailedErr);
+
+        Result := ALCopilotResponse.Result();
+    end;
+
+    local procedure GenerateJsonForSingleInput(Base64: Text): Text
+    var
+        JsonObject: JsonObject;
+        InputsObject: JsonObject;
+        InnerObject: JsonObject;
+        JsonText: Text;
+    begin
+        // Create the inner object with the base64Encoded property  
+        InnerObject.Add('base64_encoded', Base64);
+        // Create the inputs object and add the inner object to it  
+        InputsObject.Add('1', InnerObject);
+        // Create the main JSON object and add the inputs object to it  
+        JsonObject.Add('inputs', InputsObject);
+        // Convert the JSON object to text  
+        JsonObject.WriteTo(JsonText);
+        // Return the JSON text  
+        exit(JsonText);
+    end;
+
+    procedure GetAzureAIDocumentIntelligenceCategory(): Code[50]
+    begin
+        exit(AzureAiDocumentIntelligenceTxt);
+    end;
+
+    [EventSubscriber(ObjectType::Codeunit, Codeunit::"Privacy Notice", OnRegisterPrivacyNotices, '', false, false)]
+    local procedure CreatePrivacyNoticeRegistrations(var TempPrivacyNotice: Record "Privacy Notice" temporary)
+    begin
+        TempPrivacyNotice.Init();
+        TempPrivacyNotice.ID := GetAzureAIDocumentIntelligenceCategory();
+        TempPrivacyNotice."Integration Service Name" := AzureAiDocumentIntelligenceTxt;
+        if not TempPrivacyNotice.Insert() then;
+    end;
+
+
+
+}

src/System Application/App/AI/src/Azure AI Document Intelligence/AzureDocumentIntelligence.Codeunit.al

@@ -0,0 +1,64 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace System.AI.DocumentIntelligence;
+
+using System.AI;
+
+/// <summary>
+/// Azure Document Intelligence implementation.
+/// </summary>
+codeunit 7780 "Azure Document Intelligence"
+{
+    Access = Public;
+    InherentEntitlements = X;
+    InherentPermissions = X;
+
+    var
+        AzureDIImpl: Codeunit "Azure DI Impl.";
+
+
+    /// <summary>
+    /// Analyze the invoice.
+    /// </summary>
+    /// <param name="Base64Data">Data to analyze.</param>
+    /// <returns>The analyzed result.</returns>
+    [Scope('OnPrem')]
+    procedure AnalyzeInvoice(Base64Data: Text): Text
+    var
+        CallerModuleInfo: ModuleInfo;
+    begin
+        NavApp.GetCallerModuleInfo(CallerModuleInfo);
+        exit(AzureDIImpl.AnalyzeInvoice(Base64Data, CallerModuleInfo));
+    end;
+
+    /// <summary>
+    /// Analyze the Receipt.
+    /// </summary>
+    /// <param name="Base64Data">Data to analyze.</param>
+    /// <returns>The analyzed result.</returns>
+    [Scope('OnPrem')]
+    procedure AnalyzeReceipt(Base64Data: Text): Text
+    var
+        CallerModuleInfo: ModuleInfo;
+    begin
+        NavApp.GetCallerModuleInfo(CallerModuleInfo);
+        exit(AzureDIImpl.AnalyzeReceipt(Base64Data, CallerModuleInfo));
+    end;
+
+
+    /// <summary>
+    /// Sets the copilot capability that the API is running for.
+    /// </summary>
+    /// <param name="CopilotCapability">The copilot capability to set.</param>
+    [NonDebuggable]
+    procedure SetCopilotCapability(CopilotCapability: Enum "Copilot Capability")
+    var
+        CallerModuleInfo: ModuleInfo;
+    begin
+        NavApp.GetCallerModuleInfo(CallerModuleInfo);
+        AzureDIImpl.SetCopilotCapability(CopilotCapability, CallerModuleInfo, AzureDIImpl.GetAzureAIDocumentIntelligenceCategory());
+    end;
+
+}

src/System Application/App/AI/src/Azure OpenAI/AzureOpenAI.Codeunit.al

@@ -268,8 +268,9 @@ codeunit 7771 "Azure OpenAI"
         CallerModuleInfo: ModuleInfo;
     begin
         NavApp.GetCallerModuleInfo(CallerModuleInfo);
-        AzureOpenAIImpl.SetCopilotCapability(CopilotCapability, CallerModuleInfo);
+        AzureOpenAIImpl.SetCopilotCapability(CopilotCapability, CallerModuleInfo, AzureOpenAIImpl.GetAzureOpenAICategory());
     end;
+
 #if not CLEAN24
     /// <summary>
     /// Gets the approximate token count for the input.