discord: combine nixcord, vencord, vesktop

modules/discord/hm.nix

@@ -0,0 +1,68 @@
+{
+  config,
+  lib,
+  pkgs,
+  options,
+  ...
+}:
+let
+  template =
+    let
+      inherit (config.lib.stylix) colors;
+      inherit (config.stylix) fonts;
+    in
+    import ./template.nix { inherit colors fonts; };
+  cfg = config.stylix;
+in
+{
+  options.stylix.targets =
+    let
+      inherit (config.lib.stylix) mkEnableTarget;
+    in
+    {
+      vencord.enable = mkEnableTarget "Vencord" true;
+      vesktop.enable = mkEnableTarget "Vesktop" true;
+      nixcord.enable = mkEnableTarget "Nixcord" true;
+    };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      (lib.mkIf cfg.targets.vencord.enable {
+        xdg.configFile."Vencord/themes/stylix.theme.css".text = template;
+      })
+
+      (lib.mkIf cfg.targets.vesktop.enable (
+        lib.mkMerge [
+          (lib.mkIf pkgs.stdenv.hostPlatform.isLinux {
+            xdg.configFile."vesktop/themes/stylix.theme.css".text = template;
+          })
+
+          (lib.mkIf pkgs.stdenv.hostPlatform.isDarwin {
+            home.file."Library/Application Support/vesktop/themes/stylix.theme.css".text =
+              template;
+          })
+        ]
+      ))
+
+      (lib.mkIf ((config.programs ? nixcord) && cfg.targets.nixcord.enable) (
+        lib.optionalAttrs (builtins.hasAttr "nixcord" options.programs) {
+          # possible the above `hasAttr` condition is unnecessary because of the `config.programs ? nixcord` condition
+          xdg.configFile =
+            let
+              inherit (config.programs) nixcord;
+            in
+            lib.mkMerge [
+              (lib.mkIf nixcord.discord.enable {
+                "Vencord/themes/stylix.theme.css".text = template;
+              })
+
+              (lib.mkIf nixcord.vesktop.enable {
+                "vesktop/themes/stylix.theme.css".text = template;
+              })
+            ];
+          programs.nixcord.config.enabledThemes = [ "stylix.theme.css" ];
+        }
+      ))
+    ]
+  );
+}