Add a Nix Flake

.envrc

@@ -0,0 +1 @@
+use flake

.gitignore

@@ -213,3 +213,9 @@ new.json
 # Keys
 *.pem
 .ok.sql
+
+# direnv/envrc cache
+.direnv
+
+# Nix build output
+result*

crates/bindings/tests/ui/tables.rs

@@ -14,7 +14,10 @@ struct TypeParam<T> {
 struct ConstParam<const X: u8> {}
 
 #[derive(spacetimedb::SpacetimeType)]
-enum Alpha { Beta, Gamma }
+enum Alpha {
+    Beta,
+    Gamma,
+}
 
 #[spacetimedb::table(name = delta)]
 struct Delta {

crates/bindings/tests/ui/tables.stderr

@@ -118,9 +118,9 @@ note: required by a bound in `spacetimedb::spacetimedb_lib::ser::SerializeNamedP
   |                             ^^^^^^^^^ required by this bound in `SerializeNamedProduct::serialize_element`
 
 error[E0277]: `&'a Alpha` cannot appear as an argument to an index filtering operation
-  --> tests/ui/tables.rs:30:33
+  --> tests/ui/tables.rs:33:33
    |
-30 |     ctx.db.delta().compound_a().find(Alpha::Beta);
+33 |     ctx.db.delta().compound_a().find(Alpha::Beta);
    |                                 ^^^^ should be an integer type, `bool`, `String`, `&str`, `Identity`, `ConnectionId`, or `Hash`, not `&'a Alpha`
    |
    = help: the trait `for<'a> FilterableValue` is not implemented for `&'a Alpha`
@@ -145,9 +145,9 @@ note: required by a bound in `UniqueColumn::<Tbl, <Col as spacetimedb::table::Co
    |                                   ^^^^^^^^^^^^^^^ required by this bound in `UniqueColumn::<Tbl, <Col as Column>::ColType, Col>::find`
 
 error[E0277]: the trait bound `Alpha: IndexScanRangeBounds<(Alpha,), SingleBound>` is not satisfied
-  --> tests/ui/tables.rs:31:40
+  --> tests/ui/tables.rs:34:40
    |
-31 |     ctx.db.delta().compound_b().filter(Alpha::Gamma);
+34 |     ctx.db.delta().compound_b().filter(Alpha::Gamma);
    |                                 ------ ^^^^^^^^^^^^ the trait `FilterableValue` is not implemented for `Alpha`
    |                                 |
    |                                 required by a bound introduced by this call

flake.nix

@@ -0,0 +1,129 @@
+{
+  description = "A Nix-flake-based Rust development environment";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+
+    crane.url = "github:ipetkov/crane";
+
+    treefmt-nix = {
+      url = "github:numtide/treefmt-nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs =
+    {
+      self,
+      nixpkgs,
+      crane,
+      treefmt-nix,
+      rust-overlay,
+    }:
+    let
+      supportedSystems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ];
+      forEachSupportedSystem =
+        f:
+        nixpkgs.lib.genAttrs supportedSystems (
+          system:
+          f (rec {
+            pkgs = import nixpkgs {
+              inherit system;
+              overlays = [ (import rust-overlay) ];
+            };
+
+            rustToolchainFor = pkgs: pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+            rustToolchain = rustToolchainFor pkgs;
+
+            # NB: we don't need to overlay our custom toolchain for the *entire*
+            # pkgs (which would require rebuidling anything else which uses rust).
+            # Instead, we just want to update the scope that crane will use by appending
+            # our specific toolchain there.
+            craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchainFor;
+          })
+        );
+    in
+    {
+      formatter = forEachSupportedSystem (
+        { pkgs, ... }: (treefmt-nix.lib.evalModule pkgs ./treefmt.nix).config.build.wrapper
+      );
+      devShells = forEachSupportedSystem (
+        { pkgs, rustToolchain, ... }:
+        {
+          default = pkgs.mkShell {
+            packages = [
+              rustToolchain
+            ];
+          };
+        }
+      );
+      packages = forEachSupportedSystem (
+        {
+          pkgs,
+          rustToolchain,
+          craneLib,
+          ...
+        }:
+        let
+          workspaceManifest = (pkgs.lib.importTOML ./Cargo.toml).workspace.package;
+
+          # Build a workspace member, specified by its Cargo.toml
+          buildPackage =
+            manifestFile: nativeBuildInputs: overrides:
+            (
+              let
+                manifest = (pkgs.lib.importTOML manifestFile).package;
+              in
+              craneLib.buildPackage (
+                {
+                  # Only build the specified package
+                  cargoExtraArgs = "-p " + manifest.name;
+
+                  pname = manifest.name;
+                  src = ./.;
+                  version = workspaceManifest.version;
+                  strictDeps = true;
+
+                  inherit nativeBuildInputs;
+                }
+                // overrides
+              )
+            );
+        in
+        {
+          spacetimedb-cli = buildPackage (./crates/cli/Cargo.toml) (with pkgs; [
+            git
+            perl
+          ]) { };
+          spacetimedb-standalone = buildPackage (./crates/standalone/Cargo.toml) (with pkgs; [ perl ]) { };
+          spacetimedb-update = buildPackage (./crates/update/Cargo.toml) (with pkgs; [ pkg-config ]) {
+            env.OPENSSL_DIR = "${pkgs.openssl.dev}";
+            env.OPENSSL_LIB_DIR = "${pkgs.lib.getLib pkgs.openssl}/lib";
+            env.OPENSSL_NO_VENDOR = 1;
+          };
+        }
+      );
+
+      overlays.default = final: prev: {
+        spacetimedb-cli = self.packages.${final.system}.spacetimedb-cli;
+        spacetimedb-standalone = self.packages.${final.system}.spacetimedb-standalone;
+        spacetimedb-update = self.packages.${final.system}.spacetimedb-update;
+      };
+
+      nixosModules.spacetimedb =
+        { pkgs, ... }:
+        {
+          nixpkgs.overlays = [ self.overlay ];
+        };
+    };
+}

treefmt.nix

@@ -0,0 +1,8 @@
+{ ... }:
+{
+  projectRootFile = "flake.nix";
+  programs = {
+    nixfmt.enable = true;
+    rustfmt.enable = true;
+  };
+}