-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathorlistmanager.h
148 lines (141 loc) · 7.37 KB
/
orlistmanager.h
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! 2004.03.05 ORListManager [Z, GLULX]
! A small class for managing property lists; supports stacks, queues, and generic
! list access methods.
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--------------------------------------------------------------------------------------
! Created by Jim Fisher
!-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -
! License:
! This work is licensed under the Creative Commons Attribution-ShareAlike License
! (http://creativecommons.org/licenses/by-sa/1.0/).
!
! In summary: you must credit the original author(s); if you alter, transform, or
! build upon this software, you may distribute the SOURCE FORM of the resulting
! work only under a license identical to this one. Note that the ShareAlike clause
! does not affect the way in which you distribute the COMPILED FORM of works built upon
! this software. Copyright remains with the original author(s), from whom you
! must seek permission if you wish to vary any of the terms of this license.
! The author(s) would also welcome bug reports and enhancement suggestions.
!--------------------------------------------------------------------------------------
! ORListManager
! A small class for managing property lists; supports stacks, queues, and generic
! list access methods. This class is similar to the OROptionList class, which it was
! written to replace, however it does not encapsulate the managed list itself.
! All methods now require the property list as a parameter. This enables the use of
! multiple lists.
!--------------------------------------------------------------------------------------
! AutoDep:
!--------------------------------------------------------------------------------------
! To register this module with your library, add the line:
!
! #ifdef USE_ORListManager; #include "ORListManager"; #endif;
!
! to the library header file (OR_Library_Include). To use in a game, add the line:
!
! Constant USE_ORListManager;
!
! to the game file;
!--------------------------------------------------------------------------------------
! Revision History
! 2004.02.28 Initial Creation
! 2004.03.05 Fixed small assignment bug in the insert routine.
!--------------------------------------------------------------------------------------
message " Processing library extension ORListManager...";
!======================================================================================
! D E P E N D A N C I E S section (for bringing in dependant modules)
!======================================================================================
! #ifndef <REPLACEWITHINCLUDENAME>_DONEREPLACE; default USE_<REPLACEWITHINCLUDENAME> 0; message " [ORListManager forcing inclusion of <REPLACEWITHINCLUDENAME>]"; #include "<REPLACEWITHINCLUDENAME>"; #endif;
! #ifndef ORLibraryInclude; message fatalerror "ORListManager has dependences and cannot stand alone. Leverage the OR_Library_Include file to automatically meet module prerequisites."; #endif;
! -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
!======================================================================================
#ifndef LIBRARY_PARSER; #ifndef ORListManager_DONEREPLACE; constant ORListManager_DONEREPLACE; #ifdef ORListManager_DONEREPLACE; #endif; !--suppress warning
! -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
! R E P L A C E section (for code that preceeds the inclusion of PARSER)
!======================================================================================
class ORListManager
with Count[prop t;
for(t=0:t<(self.#prop/WORDSIZE):t++){
if(self.&prop-->t==0) return t;
}
return (self.#prop/WORDSIZE);
]
! , dump[prop t; print "^";
! for(t=0:t<(self.#prop/WORDSIZE):t++) print self.&prop-->t;
! ]
, Clear[prop t cnt; !--remove everything from the list
cnt=self.count(prop);
for(t=0:t<cnt:t++) {
self.Remove(prop,0);
}
]
, Get[prop n;
if(n>=self.count(prop)) "Error (ORList): index out of range (Get)";
return self.&prop-->n;
]
, Set[prop n val;
if(n>=self.count(prop)) "Error (ORList): index out of range (Set)";
self.&prop-->n=val;
]
, Find[prop Option t;
for(t=0:t<self.#prop/WORDSIZE:t++){
if(self.&prop-->t==Option){
return t;
}
}
return -1;
]
, Remove[prop number t pos; !--eliminate a position and shift everything forward
pos=((self.#prop)/WORDSIZE)-1;
for(t=number:t<pos:t++){
self.&prop-->t=self.&prop-->(t+1);
}
self.&prop-->pos=0;
]
, RemoveEntry[prop Option n; !--Locate an option and remove it
n=self.Find(prop, Option);
if(n~=-1) self.Remove(prop, n);
]
, insert[prop newOption pos t; !--add an option and associated value to the first position
if(self.count(prop)>=(self.#prop/WORDSIZE)) rfalse; !--already filled up, no room left
for(t=self.#prop/WORDSIZE-1:t>pos:t--){
self.&prop-->t=self.&prop-->(t-1);
}
self.&prop-->pos=newOption;
rtrue;
]
, insert_end[prop newOption; !--add an option and associated value to the first unused position
return self.insert(prop,newOption,self.count(prop));
]
, pop[prop pos retval;
retval=self.Get(prop,pos);
self.Remove(prop,pos);
return retval;
]
, pop_end[prop end retval;
end=self.count(prop);
if(end<1) return 0;
retval=self.Get(prop,end-1);
self.Remove(prop,end-1);
return retval;
]
;
!======================================================================================
#ifnot; message " ...Already Included. Skipping."; #endif; #ifnot; #ifndef LIBRARY_VERBLIB; #ifndef ORListManager_DONEMESSAGE; constant ORListManager_DONEMESSAGE; #ifdef ORListManager_DONEMESSAGE; #endif; !--suppress warning
! -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
! M E S S A G E section (for code that falls between PARSER and VERBLIB )
!======================================================================================
! #ifndef OREnglish; message fatalerror "ERROR!!!! ORListManager requires the OREnglish file.";#endif;
!======================================================================================
#endif; #ifnot; #ifndef LIBRARY_GRAMMAR; #ifndef ORListManager_DONECODE;constant ORListManager_DONECODE; #ifdef ORListManager_DONECODE; #endif; !--suppress warning
! -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
! C O D E section (for code that falls between VERBLIB and GRAMMAR)
!======================================================================================
!======================================================================================
#endif; #ifnot; #ifndef ORListManager_DONEGRAMMAR; constant ORListManager_DONEGRAMMAR; #ifdef ORListManager_DONEGRAMMAR; #endif; !--suppress warning
! -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
! G R A M M A R section (for code that follows the inclusion of GRAMMAR)
!======================================================================================
!======================================================================================
#endif; #endif; #endif;#endif;
!======================================================================================