Dynamically Stream Audio Files to Icecast via HTTP Request in Liquidsoap

[acrylo-code]

Question:
I’m trying to dynamically stream audio effects (or files) using Liquidsoap and Icecast, based on an HTTP request. I want to be able to send a request like http://:6001/effect?file=effect1.mp3 and have the corresponding audio file played in the stream. Here’s the Liquidsoap code I’m working with, but it seems like the request handling and streaming aren't working as expected.

Could someone help me identify what’s wrong and suggest how to properly stream the requested files to Icecast? I'm very new to LiquidSoap and don't know the language good enough to continue.

Code I have so far:

# Define Icecast server details
server = "icecast"
port = 8000
password = "***********"
mount = "stream.mp3"

# Load a local audio file (initial stream)
stream = blank()

# HTTP handler to play sound effects dynamically based on the file parameter
def handler(request, response) =
  file_name = request.query["file"]  # Extract the file query parameter
  if file_name != "" then
    effect = single("/audio/" ^ file_name)
    add([stream, effect])
    response.html("<p>Playing: #{file_name}</p>")
  else
    response.html("<p>No file specified. Please provide a valid file parameter.</p>")
  end
end

# Stream to Icecast
output.icecast(%mp3, stream, host=server, port=port, password=password, mount=mount)

# Register HTTP endpoint with GET method and correct path
harbor.http.register(port=6001, method="GET", "/effect", handler)

What I Want to Achieve:
I want to dynamically stream audio files (e.g., sound effects) to the Icecast stream based on an HTTP request.
For example, if I access the following URL: http://:6001/effect?file=effect1.mp3, I want effect1.mp3 to be played in the Icecast stream that’s available at http://:8000/stream.mp3.
I want the stream to update automatically and play the requested file.
The requested files should be able to play simultaneously

What’s Happening:
When I make a request (e.g., http://:6001/effect?file=effect1.mp3), the server responds with the message "Playing: effect1.mp3".
However, the requested audio file doesn’t actually play in the stream, and no update seems to occur in the Icecast output.

What I’ve Tried:
I’ve ensured the audio files exist in the /audio/ folder.
I’m using a simple single() function to load the audio file dynamically and attempting to add it to the stream.

What I Need Help With:
I believe I may be missing something with the way I'm dynamically adding the requested file to the stream, or with the HTTP request handling logic.
Could someone point out any issues or provide guidance on how to properly stream the requested file to Icecast?

Thanks in advance for any help!

[vitoyucepi]

Hi @acrylo-code,
Try creating a request.queue and push new tracks into it.
Here's a code snippet. I haven't checked it, so there may be some errors.

stream = blank()
effects_queue = request.queue()
radio = add([stream, effects_queue])

# Stream to Icecast
output.icecast(%mp3, stream, host=server, port=port, password=password, mount=mount)

# HTTP handler to play sound effects dynamically based on the file parameter
def handler(request, response) =
  file_name = request.query["file"]  # Extract the file query parameter

  if file_name == "" then
    response.html("<p>No file specified. Please provide a valid file parameter.</p>")
  else
    base_path = "/audio"
    file_name = path.concat(base_path, file_name)
    if not file.exists(file_name) then
      response.html("<p>Doesn't exist.</p>")
    elsif not file.is_directory(file_name)
      response.html("<p>Not a file.</p>")
    else
      effects_queue.push.uri("file_name")
      response.html("<p>Playing: #{file_name}</p>")
    end
  end
end

# Register HTTP endpoint with GET method and correct path
harbor.http.register(port=6001, method="GET", "/effect", handler)

[acrylo-code]

I got your example working with a few minor tweaks. However, I noticed that when using the queue, the sound effects play one after another instead of overlapping. My goal is to have each effect play immediately upon request, allowing multiple effects to overlap rather than waiting in a queue.

Any suggestions on how to achieve this?

[vitoyucepi]

At first I thought about creating a list of queues, adding them together, and pushing requests in a round robin fashion, but then I opened the book and found an example on page 208 that demonstrates similar behavior.
So instead of using request.queue() use request.player().

effects_player = request.player()

# HTTP handler to play sound effects dynamically based on the file parameter
def handler(request, response) =
  file_name = request.query["file"]  # Extract the file query parameter

  if file_name == "" then
    response.html("<p>No file specified. Please provide a valid file parameter.</p>")
  else
    base_path = "/audio"
    file_name = path.concat(base_path, file_name)
    if not file.exists(file_name) then
      response.html("<p>Doesn't exist.</p>")
    elsif not file.is_directory(file_name)
      response.html("<p>Not a file.</p>")
    else
      effect = request.create(file_name)
      effects_player.play(effect)
      response.html("<p>Playing: #{file_name}</p>")
    end
  end
end

[acrylo-code]

# Define Icecast server details
server = "icecast"
port = 8000
password = "**********"
mount = "stream.mp3"

# Create a dynamic source with an initial null function
effects_player = request.player()

# Main radio stream with a fallback blank source
radio = fallback(track_sensitive=false, [effects_player, blank()])

# Stream to Icecast
output.icecast(%mp3, host=server, port=port, password=password, mount=mount, radio)

# HTTP handler to dynamically change the playing effect
def handler(req, response) =
  file_name = req.query["file"]  # Extract file parameter

  if file_name == "" then
    response.html("<p>No file specified. Please provide a valid file parameter.</p>")
  else
    base_path = "/audio"
    file_path = path.concat(base_path, file_name)

    if not file.exists(file_path) then
      response.html("<p>File doesn't exist.</p>")
    else
      effect = request.create(file_path)
      log.important("Updating effects source: #{file_path}")
      effects_player.play(effect)  # Dynamically update the source
      response.html("<p>Playing: #{file_path}</p>")
    end
  end
end

# Register HTTP endpoint for triggering sound effects dynamically
harbor.http.register(port=6001, method="GET", "/effect", handler)

This is the script I have now, it does kinda work but it keeps adding sources even when no requests are coming in :

2025/03/15 16:23:28 [source.4911:3] Content type is {audio=pcm(stereo)}.
2025/03/15 16:23:28 [audio.add.4911:3] Content type is {audio=pcm(stereo)}.
2025/03/15 16:23:28 [clock.generic:2] We must catchup 33.39 seconds!
2025/03/15 16:23:28 [source.4912:3] Content type is {audio=pcm(stereo)}.

How would I prevent this? In the book on the page you mentioned they're using source.dynamic? Do i need to use something like that?

[vitoyucepi]

It seems that request.player started to behave differently since liquidsoap version 2.2.0.