loop a json node to instantiate icecast streams

[ZiTAL]

radio.json

{
    "server_port": 1234,
    "icecast":
    [
        {
            "host":     "localhost",
            "port":     8000,
            "password": "passwd",
            "type":     "mp3",
            "mount":    "/stream.mp3"
        },
        {
            "host":     "localhost",
            "port":     8000,
            "password": "passwd",
            "type":     "ogg",
            "mount":    "/stream.ogg"
        }
    ]
}

code:

let json.parse config = file.contents("radio.json")

error:

At ./radio.liq, line 5, char 0-51:
let json.parse config = file.contents("radio.json")

Error 14: Uncaught runtime error:
type: json,
message: "Parsing error: json value cannot be parsed as type {host: _, _}",
stack: at ./radio.liq, line 5, char 0-51

the json is valid, if I use a simple json there is no problem to read an use it, anyway i would like to loop the icecast node to instanciate each ones, how to deal with it?

[toots]

I think that we would need to see more of your script to be able to help.

[ZiTAL]

code:

#!/usr/bin/env liquidsoap

settings.log.file.set(false)

let json.parse config = file.contents("radio.json")

settings.server.telnet.set(true)
settings.server.telnet.port.set(config.server_port)
settings.server.telnet.bind_addr.set("0.0.0.0")

s = input.http("",          timeout=5.)
p = playlist("silence.m3u", reload_mode="manual")
b = blank()

radio   = fallback(track_sensitive = false, [s, p, b])
radio   = normalize(radio)

let icecast_list = config.icecast
list.iter(fun (ic) ->

    output.icecast(
    %mp3(bitrate=128, samplerate=44100, stereo=true),
    host=ic.host,
    port=ic.port,
    password=ic.passwd,
    mount=ic.mount,
    name="radio name",
    description="radio desc",
    genre="Various",
    url="http://radio.localhost",
    public=true,
    radio)

, icecast_list)

error:

At ./r.liq, line 5, char 0-51:
let json.parse config = file.contents("radio.json")

Error 14: Uncaught runtime error:
type: json,
message: "Parsing error: json value cannot be parsed as type {icecast: [{passwd: _, _}], _}",
stack: at ./r.liq, line 5, char 0-51

[toots]

Looks like a typo to me: ic.passwd vs ic.password

For more readability, I would suggest to annotate the expected type when parsing:

let json.parse (config : {
  server_port: int,
  icecast: [{
    host: string,
    port: int,
    password: string,
    type: string,
    mount: string
  }]
}) = file.contents("radio.json")

[ZiTAL]

you are right toots thank you, works fine, but how to replace %mp3 to use ic.type?

[toots]

Something like:

mp3_encoder = %mp3(bitrate=128, samplerate=44100, stereo=true)
ogg_encoder = %ogg(%opus)

...

list.iter(fun (ic) ->
    output.icecast(
    (ic.type == "mp3" ? mp3_encoder : ogg_encoder),
    ...)
, icecast_list)

[ZiTAL]

thank you @toots works fine, but i would like to use a function, I wrote this:

def getEncoder(type) = 
  if type == 'mp3' then
    %mp3(bitrate=128, samplerate=44100, stereo=true)
  else if type == 'ogg' then
    %ogg(%vorbis)
  end
end
...
output.icecast(
  getEncoder(ic.type),
...

and i have this error:

Unknown position:

Error 2: Parse error

[gAlleb]

def getEncoder(type) = 
type == 'mp3' ? %mp3(bitrate=128, samplerate=44100, stereo=true) : %ogg(%vorbis)
end

def getEncoder(type) = 
  if type == 'mp3' then
    %mp3(bitrate=128, samplerate=44100, stereo=true)
  elsif type == 'ogg' then
    %ogg(%vorbis)
  else
    null()
  end
end

[ZiTAL]

...
def getEncoder(type) = 
  if type == 'mp3' then
    %mp3.cbr(bitrate=128, samplerate=44100, stereo=true)
  elsif type == 'ogg' then
    %vorbis.cbr(bitrate=128, samplerate=44100, channels=2)
  else
    null()
  end
end
...
let icecast_list = config.icecast
list.iter(fun (ic) ->

  output.icecast(
    getEncoder(ic.type),
    host=ic.host,
    port=ic.port,
    password=ic.password,
    mount=ic.mount,
    name="radio name",
    description="radio desc",
    genre="Various",
    url="http://radio.localhost",
    public=true,
    radio
  )

, icecast_list)

error:

t ./radio.liq, line 83, char 4-23:
    getEncoder(ic.type),

Error 5: this value has type
  _? (inferred at ./radio.liq, line 65, char 4-56)
but it should be a subtype of
  format(_)

[gAlleb]

I suggest then just

def getEncoder(type) = 
  if type == 'mp3' then
    %mp3.cbr(bitrate=128, samplerate=44100, stereo=true)
  else
    %vorbis.cbr(bitrate=128, samplerate=44100, channels=2)
  end
end

or

def getEncoder(type) = 
type == 'mp3' ? %mp3(bitrate=128, samplerate=44100, stereo=true) : %ogg(%vorbis)
end

or change null() to any default encoder format so it would return it

def getEncoder(type) = 
  if type == 'mp3' then
    %mp3.cbr(bitrate=128, samplerate=44100, stereo=true)
  elsif type == 'ogg' then
    %vorbis.cbr(bitrate=128, samplerate=44100, channels=2)
  else
    %mp3.cbr(bitrate=128, samplerate=44100, stereo=true)
  end
end

Also %mp3 is by default cbr, samplerate=44100, stereo=true

[ZiTAL]

@gAlleb works like a charm

thank you to both @toots and @gAlleb for your patience!