change source from telnet

[ZiTAL]

the idea is not to stop the stream and stream always signal and choose what I want using telnet commands.

But, I don't know how to implement the server.register functions.

#!/usr/bin/env liquidsoap

settings.log.file.set(false)

settings.server.telnet.set(true)
settings.server.telnet.port.set(1234)
settings.server.telnet.bind_addr.set("0.0.0.0")

host    = "localhost"
port    = 8000
passwd  = "passwd"
mount   = "/stream.mp3"

p       = playlist("a.m3u", reload_mode="manual")
bi      = input.http("https://stream.mediasector.es/radio/8230/bizkaiairratia.mp3", timeout=5.)
obs     = input.http("http://localhost:1935/hls/0/stream.m3u8",                     timeout=5.)
silence = blank()

radio   = fallback(track_sensitive = false, [obs, bi, p, silence])
radio   = normalize(radio)

server.register("set_playlist",            setPlaylist)
server.register("reload_playlist",       reloadPlaylist)
server.register("set_bizkaia_irratia", setBizkaiaIrratia)
server.register("set_obs",                 setObs)

output.icecast(
  %mp3(bitrate=128, samplerate=44100, stereo=true),
  host=host,
  port=port,
  password=passwd,
  mount=mount,
  name="radio name",
  description="radio desc",
  genre="Various",
  url="http://radio.localhost",
  public=true,
  radio
)

I know that I can call it like this and works fine:

echo "reload_playlist" | nc localhost 1234

Thank you very much :)

[toots]

Hi!

You can use server.register as follows:

def reloadPlaylist(_) =
  p.reload()
  "Playlist reloaded!"
end

server.register("reload_playlist", reloadPlaylist)

That's the easy one! To set the playlist is a little more tricky. I imagine that you would do:

echo "set_playlist /path/to/playlist" | nc localhost 1234

In this case:

def setPlaylist(uri) =
  # This is how you can change the playlist,
  # reload with the optional `uri` argument set:
  p.reload(uri=uri)
  "Playlist set to #{uri}"
end

server.register("set_playlist", setPlaylist)

Essentially, the function takes what is passed to the command as first argument and returns a string to print to the caller.

[gAlleb]

@ZiTAL, you can also stop input.http sources and change their urls. #4312

[ZiTAL]

#!/usr/bin/env liquidsoap

settings.log.file.set(false)

settings.server.telnet.set(true)
settings.server.telnet.port.set(1234)
settings.server.telnet.bind_addr.set("0.0.0.0")

host    = "localhost"
port    = 8000
passwd  = "passwd"
mount   = "/stream.mp3"

p = playlist("a.m3u",   reload_mode="manual")
s = input.http("", timeout=5.)
b = blank()

radio   = fallback(track_sensitive = false, [p, s, b])
radio   = normalize(radio)

def setPlaylist(uri) =
  # echo "set_playlist /path/to/playlist" | nc localhost 1234
  p.reload(uri=uri)
  "Playlist set to #{uri}"
end

def stopPlaylist(_)
#    p.stop()
    "Playlist stopped"
end

def stopStream(_)
    s.stop()
    "Stream stopped"
end

def setStream(uri) = 
    # echo "set_stream http://stream" | nc localhost 1234
    s.stop()
    s.set_url(uri)
    s.start()
    "Stream set to #{uri}"
end

server.register("set_playlist",  setPlaylist)
server.register("stop_playlist", stopPlaylist)
server.register("set_stream",    setStream)
server.register("stop_stream",   stopStream)

output.icecast(
  %mp3(bitrate=128, samplerate=44100, stereo=true),
  host=host,
  port=port,
  password=passwd,
  mount=mount,
  name="radio name",
  description="radio desc",
  genre="Various",
  url="http://radio.localhost",
  public=true,
  radio
)

echo "set_stream https://stream.mediasector.es/radio/8230/bizkaiairratia.mp3" | nc localhost 1234
Stream set to https://stream.mediasector.es/radio/8230/bizkaiairratia.mp3
END

echo "set_playlist 0.m3u" | nc localhost 1234
Playlist set to 0.m3u
END

echo "stop_stream" | nc localhost 1234
Stream stopped
END

thank you @toots and @gAlleb works well, but how to stop the playlist that
the program says that the playlist has no "stop" function, how to deal with it?

thank you :)

[gAlleb]

Hi! I don't think playlist has stop command. But you can use interactive.bool and logic to meet your current needs. Small example:

settings.server.telnet := true
settings.server.telnet.port := 1234

# when true - playlist is stopped
pause_playlist = interactive.bool("pause_playlist",true)

p = playlist("a.m3u")
b = blank()

radio = switch(track_sensitive=false, [
  ({pause_playlist() == false}, p),
  ({true}, b)
])

output.dummy(radio)

So when you start a script - you will hear blank because pause_playlist = true. When you change it to false via telnet command var.set pause_playlist = false - your playlist will play.

Same way you can register a command so you don't have to send var.set pause_playlist = false

def pause_play_p(_) 
if pause_playlist() == true then 
pause_playlist := false
else
pause_playlist := true
end
"Playlist state toggled"
end

server.register("pause_play_playlist",  pause_play_p)

[ZiTAL]

#!/usr/bin/env liquidsoap

settings.log.file.set(false)

settings.server.telnet.set(true)
settings.server.telnet.port.set(1234)
settings.server.telnet.bind_addr.set("0.0.0.0")

host    = "localhost"
port    = 8000
passwd  = "passwd"
mount   = "/stream.mp3"

pause_playlist = interactive.bool("pause_playlist", true)

s = input.http("", timeout=5.)
p = playlist("a.m3u",   reload_mode="manual")
b = blank()

#radio   = fallback(track_sensitive = false, [s, p, b])
radio = switch(track_sensitive=false, [
  ({true}, s),
  ({pause_playlist() == false}, p),
  ({true}, b)
])
radio   = normalize(radio)

def setPlaylist(uri) =
  # echo "set_playlist /path/to/playlist" | nc localhost 1234
  p.reload(uri=uri)
  "Playlist set to #{uri}"
end

def startPlaylist(_)
    pause_playlist := false
    "Playlist started"
end

def stopPlaylist(_)
    pause_playlist := true
    "Playlist stopped"
end

def stopStream(_)
    s.stop()
    "Stream stopped"
end

def setStream(uri) = 
    # echo "set_stream http://stream" | nc localhost 1234
    s.stop()
    s.set_url(uri)
    s.start()
    "Stream set to #{uri}"
end

server.register("set_playlist",   setPlaylist)
server.register("start_playlist", startPlaylist)
server.register("stop_playlist",  stopPlaylist)
server.register("set_stream",     setStream)
server.register("stop_stream",    stopStream)

output.icecast(
  %mp3(bitrate=128, samplerate=44100, stereo=true),
  host=host,
  port=port,
  password=passwd,
  mount=mount,
  name="radio name",
  description="radio desc",
  genre="Various",
  url="http://radio.localhost",
  public=true,
  radio
)

thank you @gAlleb is working like a charm, you're awesome!