[25.x] [Copilot] Add telemetry when data movement is updated (#3321)

<!-- Thank you for submitting a Pull Request. If you're new to
contributing to BCApps please read our pull request guideline below
* https://github.com/microsoft/BCApps/Contributing.md
-->
#### Summary <!-- Provide a general summary of your changes -->
Add telemetry when data movement is updated. Also emit once during
install and upgrade to get current state.

#### Work Item(s) <!-- Add the issue number here after the #. The issue
needs to be open and approved. Submitting PRs with no linked issues or
unapproved issues is highly discouraged. -->
Fixes
[AB#571729](https://dynamicssmb2.visualstudio.com/Dynamics%20SMB/_workitems/edit/571729)

Author: stkillen

src/System Application/App/AI/app.json

@@ -29,6 +29,12 @@
       "publisher": "Microsoft",
       "version": "25.6.0.0"
     },
+    {
+      "id": "93b83ef6-9666-4c1d-b130-c232f4047621",
+      "name": "Upgrade Tags",
+      "publisher": "Microsoft",
+      "version": "25.6.0.0"
+    },
     {
       "id": "7e3b999e-1182-45d2-8b82-d5127ddba9b2",
       "publisher": "Microsoft",
@@ -90,7 +96,7 @@
   "idRanges": [
     {
       "from": 7758,
-      "to": 7778
+      "to": 7782
     }
   ],
   "target": "OnPrem",

src/System Application/App/AI/src/Copilot/CopilotAICapabilities.Page.al

@@ -248,15 +248,7 @@ page 7775 "Copilot AI Capabilities"
         OnRegisterCopilotCapability();
 
         CopilotCapabilityImpl.CheckGeoAndEUDB(WithinGeo, WithinEUDB);
-
-        case PrivacyNotice.GetPrivacyNoticeApprovalState(CopilotCapabilityImpl.GetAzureOpenAICategory(), false) of
-            Enum::"Privacy Notice Approval State"::Agreed:
-                AllowDataMovement := true;
-            Enum::"Privacy Notice Approval State"::Disagreed:
-                AllowDataMovement := false;
-            else
-                AllowDataMovement := true;
-        end;
+        CopilotCapabilityImpl.GetDataMovementAllowed(AllowDataMovement);
 
         AllowDataMovementEditable := CopilotCapabilityImpl.IsAdmin();
 
@@ -277,6 +269,8 @@ page 7775 "Copilot AI Capabilities"
     end;
 
     local procedure UpdateAllowDataMovement()
+    var
+        CopilotTelemetry: Codeunit "Copilot Telemetry";
     begin
         if AllowDataMovement then
             PrivacyNotice.SetApprovalState(CopilotCapabilityImpl.GetAzureOpenAICategory(), Enum::"Privacy Notice Approval State"::Agreed)
@@ -286,6 +280,7 @@ page 7775 "Copilot AI Capabilities"
         CurrPage.GenerallyAvailableCapabilities.Page.SetDataMovement(AllowDataMovement);
         CurrPage.PreviewCapabilities.Page.SetDataMovement(AllowDataMovement);
         CopilotCapabilityImpl.UpdateGuidedExperience(AllowDataMovement);
+        CopilotTelemetry.SendCopilotDataMovementUpdatedTelemetry(AllowDataMovement);
     end;
 
     [IntegrationEvent(false, false)]

src/System Application/App/AI/src/Copilot/CopilotCapabilityImpl.Codeunit.al

@@ -263,6 +263,20 @@ codeunit 7774 "Copilot Capability Impl"
         WithinEUDB := ALCopilotFunctions.IsWithinEUDB();
     end;
 
+    procedure GetDataMovementAllowed(var AllowDataMovement: Boolean)
+    var
+        PrivacyNotice: Codeunit "Privacy Notice";
+    begin
+        case PrivacyNotice.GetPrivacyNoticeApprovalState(GetAzureOpenAICategory(), false) of
+            Enum::"Privacy Notice Approval State"::Agreed:
+                AllowDataMovement := true;
+            Enum::"Privacy Notice Approval State"::Disagreed:
+                AllowDataMovement := false;
+            else
+                AllowDataMovement := true;
+        end;
+    end;
+
     procedure UpdateGuidedExperience(AllowDataMovement: Boolean)
     var
         GuidedExperience: Codeunit "Guided Experience";

src/System Application/App/AI/src/Copilot/CopilotTelemetry.Codeunit.al

@@ -5,6 +5,7 @@
 namespace System.AI;
 
 using System.Telemetry;
+using System.Globalization;
 
 /// <summary>
 /// This codeunit is called from Platform.
@@ -21,6 +22,7 @@ codeunit 7775 "Copilot Telemetry"
         AppId: Guid;
         TelemetryFeedbackOnCopilotCapabilityLbl: Label 'Feedback on Copilot Capability.', Locked = true;
         TelemetryActionInvokedOnCopilotCapabilityLbl: Label 'Action invoked on Copilot Capability.', Locked = true;
+        TelemetryAllowDataMovementUpdatedLbl: Label 'Allow data movement was updated.', Locked = true;
 
     procedure SetCopilotCapability(NewCopilotCapability: Enum "Copilot Capability"; NewAppId: Guid)
     begin
@@ -47,4 +49,40 @@ codeunit 7775 "Copilot Telemetry"
             CopilotCapabilitiesImpl.AddTelemetryDimensions(CopilotCapability, AppId, CustomDimensions);
         FeatureTelemetry.LogUsage('0000LLW', CopilotCapabilitiesImpl.GetCopilotCategory(), TelemetryActionInvokedOnCopilotCapabilityLbl, CustomDimensions);
     end;
+
+    procedure SendCopilotDataMovementUpdatedTelemetry()
+    var
+        CopilotCapabilityImpl: Codeunit "Copilot Capability Impl";
+        AllowDataMovement: Boolean;
+    begin
+        CopilotCapabilityImpl.GetDataMovementAllowed(AllowDataMovement);
+
+        SendCopilotDataMovementUpdatedTelemetry(AllowDataMovement);
+    end;
+
+    procedure SendCopilotDataMovementUpdatedTelemetry(AllowDataMovement: Boolean)
+    var
+        CopilotCapabilitiesImpl: Codeunit "Copilot Capability Impl";
+        FeatureTelemetry: Codeunit "Feature Telemetry";
+        Language: Codeunit Language;
+        CustomDimensions: Dictionary of [Text, Text];
+        WithinGeo: Boolean;
+        WithinEUDB: Boolean;
+        SavedGlobalLanguageId: Integer;
+    begin
+        CopilotCapabilitiesImpl.CheckGeoAndEUDB(WithinGeo, WithinEUDB);
+
+        SavedGlobalLanguageId := GlobalLanguage();
+
+        GlobalLanguage(Language.GetDefaultApplicationLanguageId());
+
+        CustomDimensions.Add('Category', CopilotCapabilitiesImpl.GetCopilotCategory());
+        CustomDimensions.Add('AllowDataMovement', Format(AllowDataMovement));
+        CustomDimensions.Add('WithinGeo', Format(WithinGeo));
+        CustomDimensions.Add('WithinEUDB', Format(WithinEUDB));
+
+        GlobalLanguage(SavedGlobalLanguageId);
+
+        FeatureTelemetry.LogUsage('0000OQK', CopilotCapabilitiesImpl.GetCopilotCategory(), TelemetryAllowDataMovementUpdatedLbl, CustomDimensions);
+    end;
 }

src/System Application/App/AI/src/Copilot/CopilotTelemetryInstall.Codeunit.al

@@ -0,0 +1,19 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace System.AI;
+
+codeunit 7782 "Copilot Telemetry Install"
+{
+    Subtype = Install;
+    InherentEntitlements = X;
+    InherentPermissions = X;
+
+    trigger OnInstallAppPerDatabase()
+    var
+        CopilotTelemetryUpgrade: Codeunit "Copilot Telemetry Upgrade";
+    begin
+        CopilotTelemetryUpgrade.SendCopilotDataMovementUpgradeTelemetry();
+    end;
+}

src/System Application/App/AI/src/Copilot/CopilotTelemetryUpgrade.Codeunit.al

@@ -0,0 +1,48 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace System.AI;
+
+using System.Upgrade;
+using System.Environment;
+
+codeunit 7781 "Copilot Telemetry Upgrade"
+{
+    Subtype = Upgrade;
+    InherentEntitlements = X;
+    InherentPermissions = X;
+
+    trigger OnUpgradePerDatabase()
+    begin
+        SendCopilotDataMovementUpgradeTelemetry();
+    end;
+
+    internal procedure SendCopilotDataMovementUpgradeTelemetry()
+    var
+        UpgradeTag: Codeunit "Upgrade Tag";
+        CopilotTelemetry: Codeunit "Copilot Telemetry";
+        EnvironmentInformation: Codeunit "Environment Information";
+    begin
+        if EnvironmentInformation.IsOnPrem() then
+            exit;
+
+        if UpgradeTag.HasUpgradeTag(GetSendCopilotDataMovementUpgradeTelemetryTag(), '') then
+            exit;
+
+        CopilotTelemetry.SendCopilotDataMovementUpdatedTelemetry();
+
+        UpgradeTag.SetUpgradeTag(GetSendCopilotDataMovementUpgradeTelemetryTag());
+    end;
+
+    [EventSubscriber(ObjectType::Codeunit, Codeunit::"Upgrade Tag", OnGetPerDatabaseUpgradeTags, '', false, false)]
+    local procedure RegisterUpgradeTags(var PerDatabaseUpgradeTags: List of [Code[250]])
+    begin
+        PerDatabaseUpgradeTags.Add(GetSendCopilotDataMovementUpgradeTelemetryTag());
+    end;
+
+    local procedure GetSendCopilotDataMovementUpgradeTelemetryTag(): Text[250]
+    begin
+        exit('MS-561464-CopilotDataMovement-20250212');
+    end;
+}