Jenkinsfile.cometd-snapshot

#!groovy

pipeline {
  agent { node { label 'linux' } }
  triggers {
    cron '@daily'
  }
  tools {
    maven 'maven3'
  }
  options {
    buildDiscarder logRotator( numToKeepStr: '5' )
  }

  stages {
    stage("Cometd 5.0.x"){
      steps{
        buildIt("jetty-9.4.x", "5.0.x", "jdk11")
      }
    }
    stage("Cometd 6.0.x"){
      steps{
        buildIt("jetty-10.0.x", "6.0.x", "jdk11")
      }
    }
    stage("Cometd 7.0.x"){
      steps{
        buildIt("jetty-11.0.x", "7.0.x", "jdk17")
      }
    }
  }
}

def buildIt(jettyBranch, cometdBranch, jdk){
  sh "wget -q -O $jettyBranch https://raw.githubusercontent.com/eclipse/jetty.project/$jettyBranch/pom.xml"
  script {
    def model = readMavenPom file: "$jettyBranch"
    jetty_version = model.getVersion()
  }
  echo "Jetty version $jetty_version"
  checkout([$class: 'GitSCM',
            branches: [[name: "*/$cometdBranch"]],
            extensions: [[$class: 'CloneOption', depth: 1, noTags: true, shallow: true]],
            userRemoteConfigs: [[url: 'https://github.com/cometd/cometd.git']]])  
  script {
    try {
      withEnv(["JAVA_HOME=${ tool "$jdk" }",
               "PATH+MAVEN=${ tool "$jdk" }/bin",
               "MAVEN_OPTS=-Xms2g -Xmx4g -Djava.awt.headless=true"]) {
        configFileProvider(
                [configFile(fileId: 'oss-deploy', variable: 'GLOBAL_MVN_SETTINGS')]) {
          sh "mvn -T2 --no-transfer-progress -s $GLOBAL_MVN_SETTINGS -Djetty.version=$jetty_version -Pci -V -B -e clean install"
        }
      }
    }
    finally
    {
      junit testResults: '**/target/surefire-reports/*.xml,**/target/invoker-reports/TEST*.xml', allowEmptyResults: true
    }
  }
}