Help with expectRevert Usage

[TheGreatAxios]

Hi team!

Hoping I can get a bit of support as I've combed through issues and deep dived into the specific section of the docs on this, but can't seem to make sense of why I'm still not having the purposed revert be a failed test.

Version: foundryup: 1.0.1, Apple Mac Silicon, Sequoia 15.3.1
Project: https://github.com/Dirt-Road-Development/monorail-contracts

Problem Location: https://github.com/Dirt-Road-Development/monorail-contracts/tree/thegreataxios/hotfix/fix-native-bridgerace-condition in ./test/unit/RaceCondition.sol

Problem: This is a two-way liquidity bridge with a center-chain (SKALE) being the "hub" where tokens are bridged too. During research yesterday I determined that there are a couple possible race conditions that I need to add security checks for within the actual contract (e.g add deposits by endpoint/chain) and that should solve the actual problem. However, I want to have this fully tested to ensure that the problem is being addressed fully. However, the test suite is not working as expected.

/*
     * @notice This functions bridges from SKALE to some arbitrary chain
     * @param tokenA The token on SKALE Chain
     * @param tokenB The token on arbitrary chain
     */
    function _bridgeFromSkaleStation(uint256 amount, IERC20Metadata tokenA, IERC20Metadata tokenB, NativeStation station, uint32 dstEndpointId) internal {

        uint256 startingTokenAUserBalance = tokenA.balanceOf(address(this));
        uint256 startingTokenBUserBalance = tokenB.balanceOf(address(this));
        uint256 startingFeeCollectorBalance = tokenA.balanceOf(feeCollector);
        
        // 1 Approve
        tokenA.approve(address(aSkaleStation), amount);
        
        // 2 Trip Details
        LibTypesV1.TripDetails memory details = LibTypesV1.TripDetails(address(tokenA), address(this), amount);
        
        // 3 Get Quote Fee
        MessagingFee memory fee = aSkaleStation.quote(dstEndpointId, details, options, false);
        
        skl.approve(address(aSkaleStation), fee.nativeFee);

        // 4 Bridge to A
        aSkaleStation.bridge(dstEndpointId, details, fee, options);
        
        // 5 Deliver
        verifyPackets(dstEndpointId, addressToBytes32(address(station)));
 
        /*
         * @notice Use tokenB since fee is taken from chain b 
         */
        (uint256 userAmount, uint256 protocolFee) = _getFee(amount, IERC20Metadata(tokenA).decimals());
        
        // 7 Check Balance
        // Notice -> the user balance is subtracted on token A
        // Notice -> the protoocl fee is increase on token A
        // Notice -> the user amount is added to token B        
        assertEq(tokenA.balanceOf(address(this)), startingTokenAUserBalance - amount);
        assertEq(tokenA.balanceOf(feeCollector), protocolFee + startingFeeCollectorBalance);
        assertEq(tokenB.balanceOf(address(this)), startingTokenBUserBalance + userAmount);
    }

I have this internal function which is using LayerZero to from SKALE -> Arbitrary Chain.

    /**
     * @dev Called when data is received from the protocol. It overrides the equivalent function in the parent contract.
     * Protocol messages are defined as packets, comprised of the following parameters.
     * @param _origin A struct containing information about where the packet came from.
     * @param _guid A global unique identifier for tracking the packet.
     * @param payload Encoded message.
     */
    function _lzReceive(
        Origin calldata _origin,
        bytes32 _guid,
        bytes calldata payload,
        address, // Executor address as specified by the OApp.
        bytes calldata // Any extra data or options to trigger on receipt.
    ) internal virtual override {
        // Decode the payload to get the message
        // In this case, type is string, but depends on your encoding!
        LibTypesV1.TripDetails memory details = abi.decode(payload, (LibTypesV1.TripDetails));

        if (tokenMappings[details.token] == address(0)) {
            revert("Invalid Token");
        }

        IERC20 localToken = IERC20(tokenMappings[details.token]);

        if (deposits[localToken] < details.amount) {
            // revert InsufficentFundsInBridge(deposits[localToken], details.amount);
            revert InsufficentFundsInBridge();
        }

        localToken.safeTransfer(details.to, details.amount);

        deposits[localToken] -= details.amount;

        emit BridgeReceived(address(localToken), details.to, details.amount);
    }

My modified layer zero receive function is where I'm throwing the error InsufficientFundsInBridge()

    /// forge-config: default.allow_internal_expect_revert = true
    function test_InsufficientExitSupply() public {
        
        (uint256 userAmount, uint256 protocolFee) = _getFee(HUNDRED_USDC, aUSDC.decimals());
        
        _bridgeToSkaleStation(HUNDRED_USDC, bUSDC, aUSDC, bStation);
        _bridgeFromSkaleStation(userAmount, aUSDC, dUSDC, dStation, D_EID);

        vm.expectRevert();
        // vm.expectRevert(InsufficentFundsInBridge.selector);
        // vm.expectRevert(abi.encodeWithSelector(InsufficentFundsInBridge.selector, 0, userAmount));
    }

I have this public test function (which I've tried naming changes as well e.g test_RevertWhen_Insuficient) that I want to catch the revert as part of my step 1. While in theory, once I fix the exit condition I won't need this function, I still want to solve this so I understand how in the recent version of Foundry to catch thrown errors that are nested like this.

What I've Tried

1. Using the forge-config comment
2. Using the global foundry setting
3. Multiple selector names
4. Using RevertWhen and Revert in the test function name

Thanks for any support here!

[TheGreatAxios]

Update: Read through the docs again and saw that I should be expecting revert before the call.

/// forge-config: default.allow_internal_expect_revert = true
    function test_RevertWhen_InsufficientExitSupply() public {
        
        (uint256 userAmount, uint256 protocolFee) = _getFee(HUNDRED_USDC, aUSDC.decimals());
        
        _bridgeToSkaleStation(HUNDRED_USDC, bUSDC, aUSDC, bStation);
    
        vm.expectRevert(InsufficentFundsInBridge.selector);
        _bridgeFromSkaleStation(userAmount, aUSDC, dUSDC, dStation, D_EID);
    }

Expecting the revert before using either the selector or just vm.expectRevert() with no selector results in no error throwing at all:

However, if I remove the expect revert; then it does revert but I can't catch it

/// forge-config: default.allow_internal_expect_revert = true
    function test_RevertWhen_InsufficientExitSupply() public {
        
        (uint256 userAmount, uint256 protocolFee) = _getFee(HUNDRED_USDC, aUSDC.decimals());
        
        _bridgeToSkaleStation(HUNDRED_USDC, bUSDC, aUSDC, bStation);
        _bridgeFromSkaleStation(userAmount, aUSDC, dUSDC, dStation, D_EID);
    }

Thanks!

[TheGreatAxios]

Update 2: Moving the functions to the top level test solved it (of course):

    function testRevert_failsWithInsufficientLiquidity() public {
        // _bridgeAllStableToASkaleStation(HUNDRED_USDC);
        _bridgeToSkaleStation(HUNDRED_USDC, bUSDC, aUSDC, bStation);
        // _bridgeFromSkaleStation(25e6, aUSDC, dUSDC, dStation, D_EID, true);
        LibTypesV1.TripDetails memory details = LibTypesV1.TripDetails(address(aUSDC), address(this), 25e6);
        MessagingFee memory fee = aSkaleStation.quote(D_EID, details, options, false);
        skl.approve(address(aSkaleStation), fee.nativeFee);
        aUSDC.approve(address(aSkaleStation), 25e6);
        
        (uint256 userAmount, ) = _getFee(25e6, aUSDC.decimals());
        vm.expectRevert(abi.encodeWithSelector(
            TokenSupplyInsufficentForChain.selector,
            userAmount,
            0,
            D_EID
        ));
        aSkaleStation.bridge(D_EID, details, fee, options);
    }

Goal: Figure out how to allow the error to revert somewhere in the internal call so that I can make the test suite far more reusable.