Maintenance utility package (#496)

Utilities which are to be used, or mainly used, in the REPL by Common
Lisp track maintainers/authors.

To start some functions for stubbing out a concept or concept
exercise.

Author: verdammelt

src/ex-maint-utils.asd

@@ -0,0 +1,16 @@
+(defsystem "ex-maint-utils"
+  :description "Exercism utilities for track maintenance"
+  :version "0.0.1"
+  :author "Mark Simpson"
+  :mailto "[email protected]"
+
+  :depends-on ("alexandria")
+
+  :pathname "ex-maint-utils"
+  :serial t
+  :components ((:module "stubs"
+                :components ((:file "package")
+                             (:file "utils")
+                             (:file "concepts")
+                             (:file "concept-exercises")))
+               (:file "package")))

src/ex-maint-utils/package.lisp

@@ -0,0 +1,4 @@
+(defpackage #:ex-maint-utils
+  (:use :cl :stubs)
+  (:export :stub-concept
+           :stub-concept-exercise))

src/ex-maint-utils/stubs/concept-exercises.lisp

@@ -0,0 +1,31 @@
+(in-package :stubs)
+
+(defun stub-concept-exercise (name)
+  (let ((exercise-directory (subdir (relative-directory "exercises" "concept") name)))
+
+    (let ((meta-directory (subdir exercise-directory ".meta")))
+      (format-to-file (file-in-dir meta-directory "exemplar.lisp")
+                      (lisp-todo "exemplar code"))
+      (format-to-file (file-in-dir meta-directory "config.json")
+                      "{\"blurb\": ~S,~
+                        \"authors\": [~S],~
+                        \"files\": {\"solution\": [\"~A.lisp\"], ~:*~
+                                    \"test\": [\"~A-test.lisp\"], ~
+                                    \"exemplar\": [\".meta/exemplar.lisp\"]}}"
+                      (todo name)
+                      *github-username* name))
+
+    (let ((docs-directory (subdir exercise-directory ".docs")))
+      (format-to-file (file-in-dir docs-directory "introduction.md")
+                      (todo "introduction"))
+      (format-to-file (file-in-dir docs-directory "instructions.md")
+                      (todo "instructions"))
+      (format-to-file (file-in-dir docs-directory "hints.md")
+                      (todo "hints")))
+
+    (format-to-file (file-in-dir exercise-directory (format nil "~A-test.lisp" name))
+                    (lisp-todo "test file"))
+    (format-to-file (file-in-dir exercise-directory (format nil "~A.lisp" name))
+                    (lisp-todo "stub file"))
+
+    (recursive-listing exercise-directory)))

src/ex-maint-utils/stubs/concepts.lisp

@@ -0,0 +1,24 @@
+(in-package :stubs)
+
+(defun stub-concept (concept)
+  (let ((concept-directory (subdir (relative-directory "concepts") concept)))
+
+    (format-to-file
+     (file-in-dir (subdir concept-directory ".meta") "config.json")
+     "{\"blurb\": ~S, \"authors\": [~S]}"
+     (todo "blurb") *github-username*)
+
+    (format-to-file
+     (file-in-dir concept-directory "introduction.md")
+     "# Introduction~%~%~A~%" (todo "introduction to ~A" concept))
+
+    (format-to-file
+     (file-in-dir concept-directory "about.md")
+     "# About~%~%~A~%" (todo "about ~A" concept))
+
+    (format-to-file
+     (file-in-dir concept-directory "links.json")
+     "[{\"url\": \"https://~A-link.html\", ~
+        \"description\": ~S}]" concept (todo "link to ~A" concept))
+
+    (recursive-listing concept-directory)))

src/ex-maint-utils/stubs/package.lisp

@@ -0,0 +1,4 @@
+(defpackage :stubs
+  (:use :cl)
+  (:export :stub-concept
+           :stub-concept-exercise))

src/ex-maint-utils/stubs/utils.lisp

@@ -0,0 +1,30 @@
+(in-package :stubs)
+
+(defun relative-directory (&rest dirs)
+  (make-pathname :directory `(:relative ,@dirs)))
+
+(defun file-in-dir (dir file) (merge-pathnames file dir))
+(defun subdir (parent dir) (merge-pathnames (relative-directory dir) parent))
+
+(defun recursive-listing (directory)
+  (directory (merge-pathnames
+              (make-pathname :directory '(:relative :wild-inferiors) :name :wild :type :wild)
+              directory)))
+
+(defparameter *github-username* "sir-not-appearing-in-this-film")
+
+(defun format-to-file (pathname string &rest args)
+  "Applies FORMAT to STRING and ARGS and outputs it to PATHNAME.
+Will overwrite PATHNAME if it already exists.
+Ensures directories leading to PATHNAME exist."
+  (ensure-directories-exist pathname)
+  (with-open-file (stream pathname :direction :output :if-exists :supersede)
+    (apply #'format stream string args)))
+
+(defun comment (tag str &optional (prefix ""))
+  (format nil "~A ~A: ~A" prefix tag str))
+
+(defun todo (string &rest args)
+  (comment "TODO" (apply #'format nil string args)))
+(defun lisp-todo (string &rest args)
+  (comment "TODO" (apply #'format nil string args) ";;"))