build.gradle

apply plugin: 'java'
apply plugin: 'maven'

group 'com.excelmicro.lib.fx'
version '1.1.0'

sourceCompatibility = 1.8

repositories {
  mavenCentral()
  maven { url "https://raw.github.com/synergian/wagon-git/releases" }
  maven {
    credentials {
      username BB_USERNAME
      password BB_PASSWORD
    }
    url "https://api.bitbucket.org/1.0/repositories/excelmicro/maven/raw/releases"
  }
}
configurations {
  deployerJar
}

dependencies {
  deployerJar "ar.com.synergian:wagon-git:0.2.5"
  deployerJar "org.apache.maven.wagon:wagon-ssh:2.2+"
}

task sourceJar(type: Jar, dependsOn: classes) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

task javadoc(overwrite: true, type: Javadoc) {
  source = sourceSets.main.allJava
  destinationDir = file("${project.projectDir}/docs/")
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

artifacts {
  archives jar
  archives sourceJar
  archives javadocJar
}

javadoc {
  source = sourceSets.main.allJava
}

uploadArchives {

  repositories {
    mavenDeployer {
      configuration = configurations.deployerJar

      repository( url: "git:releases://git@bitbucket.org:excelmicro/maven.git") {
        authentication( userName: BB_USERNAME, password: BB_PASSWORD )
      }

      pom.project {
        name 'com.excelmicro.lib.fx:Toaster'
        packaging 'jar'
        description 'Tiny JavaFX Toast Notification Implementation'
        url 'https://github.com/excelmicro/FX-Toaster'

        inceptionYear '2017'

        organization {
          name 'Excel Micro LLC'
          url 'http://www.excelmicro.com/'
        }

        developers {
          developer {
            name 'Elizabeth Harper'
            email 'elliefops@gmail.com'
          }
        }
      }
    }
  }
}