-
Notifications
You must be signed in to change notification settings - Fork 4
/
Copy pathYY_PAO_MONEY_CHAPTER13.abap
257 lines (210 loc) · 6.87 KB
/
YY_PAO_MONEY_CHAPTER13.abap
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
*&---------------------------------------------------------------------*
*& The Money Example for Test-Driven Development in ABAP
*& based on TDD by Example: Part 1; Chapter 13
*&---------------------------------------------------------------------*
PROGRAM yy_pao_money_chapter13.
"" $5 + 10 CHF = $10 if rate is 2:1
** $5 + $5 = $10
"" Return Money from $5 + $5
"" Bank->reduce( Money )
"" Reduce Money with conversion
"" Reduce( Bank, Currency )
*& Production Code
CLASS lcl_money DEFINITION DEFERRED.
INTERFACE lif_expression.
METHODS:
reduce
IMPORTING iv_to TYPE currency
RETURNING VALUE(ro_result) TYPE REF TO lcl_money.
ENDINTERFACE.
CLASS lcl_money DEFINITION.
PUBLIC SECTION.
INTERFACES:
lif_expression.
ALIASES:
reduce FOR lif_expression~reduce.
CLASS-METHODS:
dollar
IMPORTING iv_amount TYPE i
RETURNING VALUE(ro_dollar) TYPE REF TO lcl_money,
franc
IMPORTING iv_amount TYPE i
RETURNING VALUE(ro_franc) TYPE REF TO lcl_money.
METHODS:
constructor
IMPORTING iv_amount TYPE i
iv_currency TYPE currency,
plus
IMPORTING io_addend TYPE REF TO lcl_money
RETURNING VALUE(ro_sum) TYPE REF TO lif_expression,
times
IMPORTING iv_multiple TYPE i
RETURNING VALUE(ro_product) TYPE REF TO lcl_money,
equals
IMPORTING iv_data_object TYPE data
RETURNING VALUE(rv_result) TYPE abap_bool,
amount
RETURNING VALUE(rv_amount) TYPE i,
currency
RETURNING VALUE(rv_currency) TYPE currency.
PRIVATE SECTION.
DATA:
mv_amount TYPE i,
mv_currency TYPE currency.
ENDCLASS.
CLASS lcl_sum DEFINITION.
PUBLIC SECTION.
INTERFACES
lif_expression.
ALIASES:
reduce FOR lif_expression~reduce.
METHODS:
constructor
IMPORTING io_augend TYPE REF TO lcl_money
io_addend TYPE REF TO lcl_money,
augend
RETURNING VALUE(ro_augend) TYPE REF TO lcl_money,
addend
RETURNING VALUE(ro_addend) TYPE REF TO lcl_money.
PRIVATE SECTION.
DATA:
mo_augend TYPE REF TO lcl_money,
mo_addend TYPE REF TO lcl_money.
ENDCLASS.
CLASS lcl_bank DEFINITION.
PUBLIC SECTION.
METHODS:
reduce
IMPORTING io_source TYPE REF TO lif_expression
iv_to TYPE currency
RETURNING VALUE(ro_result) TYPE REF TO lcl_money.
ENDCLASS.
CLASS lcl_money IMPLEMENTATION.
METHOD dollar.
ro_dollar = NEW lcl_money( iv_amount = iv_amount
iv_currency = |USD| ).
ENDMETHOD.
METHOD franc.
ro_franc = NEW lcl_money( iv_amount = iv_amount
iv_currency = |CHF| ).
ENDMETHOD.
METHOD constructor.
mv_amount = iv_amount.
mv_currency = iv_currency.
ENDMETHOD.
METHOD plus.
ro_sum = NEW lcl_sum( io_augend = me
io_addend = io_addend ).
ENDMETHOD.
METHOD times.
ro_product = NEW lcl_money( iv_amount = amount( ) * iv_multiple
iv_currency = currency( ) ).
ENDMETHOD.
METHOD equals.
DATA(lo_money) = CAST lcl_money( iv_data_object ).
rv_result = xsdbool( amount( ) = lo_money->amount( ) AND
currency( ) = lo_money->currency( ) ).
ENDMETHOD.
METHOD reduce.
ro_result = me.
ENDMETHOD.
METHOD amount.
rv_amount = mv_amount.
ENDMETHOD.
METHOD currency.
rv_currency = mv_currency.
ENDMETHOD.
ENDCLASS.
CLASS lcl_sum IMPLEMENTATION.
METHOD constructor.
mo_augend = io_augend.
mo_addend = io_addend.
ENDMETHOD.
METHOD reduce.
DATA(lv_amount) = augend( )->amount( ) + addend( )->amount( ).
ro_result = NEW lcl_money( iv_amount = lv_amount
iv_currency = iv_to ).
ENDMETHOD.
METHOD augend.
ro_augend = mo_augend.
ENDMETHOD.
METHOD addend.
ro_addend = mo_addend.
ENDMETHOD.
ENDCLASS.
CLASS lcl_bank IMPLEMENTATION.
METHOD reduce.
ro_result = io_source->reduce( iv_to ).
ENDMETHOD.
ENDCLASS.
*& Test Code
CLASS ltc_example DEFINITION
INHERITING FROM cl_aunit_assert
FOR TESTING RISK LEVEL HARMLESS.
PRIVATE SECTION.
METHODS:
multiplication FOR TESTING,
equality FOR TESTING,
currency FOR TESTING,
simple_addition FOR TESTING,
plus_returns_sum FOR TESTING,
reduce_sum FOR TESTING,
reduce_money FOR TESTING.
ENDCLASS.
CLASS ltc_example IMPLEMENTATION.
METHOD multiplication.
DATA(lo_five) = lcl_money=>dollar( 5 ).
assert_equals( exp = abap_true
act = lo_five->times( 2 )->equals( lcl_money=>dollar( 10 ) ) ).
assert_equals( exp = abap_true
act = lo_five->times( 3 )->equals( lcl_money=>dollar( 15 ) ) ).
ENDMETHOD.
METHOD equality.
assert_equals( exp = abap_true
act = lcl_money=>dollar( 5 )->equals( lcl_money=>dollar( 5 ) ) ).
assert_equals( exp = abap_false
act = lcl_money=>dollar( 5 )->equals( lcl_money=>dollar( 6 ) ) ).
assert_equals( exp = abap_false
act = lcl_money=>franc( 5 )->equals( lcl_money=>dollar( 5 ) ) ).
ENDMETHOD.
METHOD currency.
assert_equals( exp = |USD|
act = lcl_money=>dollar( 1 )->currency( ) ).
assert_equals( exp = |CHF|
act = lcl_money=>franc( 1 )->currency( ) ).
ENDMETHOD.
METHOD simple_addition.
DATA(lo_five) = lcl_money=>dollar( 5 ).
DATA(lo_sum) = lo_five->plus( lo_five ).
DATA(lo_bank) = NEW lcl_bank( ).
DATA(lo_reduced) = lo_bank->reduce( io_source = lo_sum
iv_to = |USD| ).
assert_equals( exp = abap_true
act = lo_reduced->equals( lcl_money=>dollar( 10 ) ) ).
ENDMETHOD.
METHOD plus_returns_sum.
DATA(lo_five) = lcl_money=>dollar( 5 ).
DATA(lo_result) = lo_five->plus( lo_five ).
DATA(lo_sum) = CAST lcl_sum( lo_result ).
assert_equals( exp = lo_five
act = lo_sum->augend( ) ).
assert_equals( exp = lo_five
act = lo_sum->addend( ) ).
ENDMETHOD.
METHOD reduce_sum.
DATA(lo_sum) = NEW lcl_sum( io_addend = lcl_money=>dollar( 3 )
io_augend = lcl_money=>dollar( 4 ) ).
DATA(lo_bank) = NEW lcl_bank( ).
DATA(lo_result) = lo_bank->reduce( io_source = lo_sum
iv_to = |USD| ).
assert_equals( exp = abap_true
act = lo_result->equals( lcl_money=>dollar( 7 ) ) ).
ENDMETHOD.
METHOD reduce_money.
DATA(lo_bank) = NEW lcl_bank( ).
DATA(lo_result) = lo_bank->reduce( io_source = lcl_money=>dollar( 1 )
iv_to = |USD| ).
assert_equals( exp = abap_true
act = lo_result->equals( lcl_money=>dollar( 1 ) ) ).
ENDMETHOD.
ENDCLASS.