Example: healing aura

[armoha]

• All zerglings heal owned and allies' hydralisks near 5x5 area by +4 HP / second (+1 HP / 6 frames)
• No stacking
  hydralisk close to multiple zerglings -> still +4 HP / second
• You can apply this to other aura or AoE skills

const zerglings = EUDVArray(30)();
var zerglingCount = 0;
var zerglingTrg = zerglings;
var zerglingPos = EPD(zerglings) + 87;
function newUnitLoop() {
    foreach(ptr, epd : EUDLoopNewUnit()) {
        const unitType = epd + 25;
        // search newly created zergling and register to varray
        // NOTE: zergling morphed from larva is not newly created unit.
        // you must have collections of larva and egg and loop them
        if (MemoryEPD(unitType, Exactly, $U("Zerg Zergling"))) {
            zerglingCount += 1;
            dwwrite_epd(zerglingPos, epd);
            zerglingTrg += 72;
            zerglingPos += 18;
        }
    }
}

var healAuraDelay;
function zerglingLoop() {
    if (zerglingCount == 0) return;
    if (healAuraDelay == 0) {
        // temporarily turn on shield usage of hydralisk
        bwrite(0x6647B0 + $U("Zerg Hydralisk"), true);
    }

    // reverse-iterating varray
    var trg, pos = zerglingTrg, zerglingPos;
    while (trg > zerglings) {
        trg -= 72;
        pos -= 18;
        var epd;
        const afterJump = Forward();
        dwwrite_epd(pos - 1, EPD(epd.getValueAddr()));
        dwwrite_epd(pos - 86, afterJump);
        EUDJump(trg);
        afterJump.__lshift__(NextTrigger());

        const epd4C = epd + 19;
        if (healAuraDelay == 0) {
            setloc_epd("loc", epd + 10);
            dilateloc("loc", 5 * 32 / 2, 5 * 32 / 2);
            const owner = maskread_epd(epd4C, 15);
            SetCurrentPlayer(owner);
            ModifyUnitShields(All, "Zerg Hydralisk", CurrentPlayer, "loc", 0);
            ModifyUnitShields(All, "Zerg Hydralisk", Allies, "loc", 0);
            ModifyUnitShields(All, "Zerg Hydralisk", NeutralPlayers, "loc", 0);
        }

        // remove dead zergling from array
        if (MemoryXEPD(epd4C, Exactly, 0, 0xFF00)) {
            zerglingCount -= 1;
            zerglingTrg -= 72;
            zerglingPos -= 18;
            if (zerglingCount > 0) {
                const afterJump = Forward();
                dwwrite_epd(zerglingPos - 1, EPD(epd.getValueAddr()));
                dwwrite_epd(zerglingPos - 86, afterJump);
                EUDJump(zerglingTrg);
                afterJump.__lshift__(NextTrigger());
                dwwrite_epd(pos, epd);
            }
        }
    }
}

function allUnitLoop() {
    foreach(ptr, epd : EUDLoopUnit2()) {
        const unitType = epd + 25;
        if (healAuraDelay == 0
        && MemoryEPD(unitType, Exactly, $U("Zerg Hydralisk"))
        && MemoryEPD(epd + 24, Exactly, 0)) {
            dwwrite_epd(epd + 24, 1);
            dwadd_epd(epd + 2, 256);
        }
    }
}

const healAuraDelayMax = 6;  // frame
function main() {
    newUnitLoop();
    zerglingLoop();
    allUnitLoop();

    if (healAuraDelay == 0) {
        healAuraDelay = healAuraDelayMax;
        bwrite(0x6647B0 + $U("Zerg Hydralisk"), false);
    } else {
        healAuraDelay -= 1;
    }
}

function afterTriggerExec() {
    main();
    dwrite(0x6509A0, 0);  // EUDTurbo
}

[TAEKHi]

Dear Artanis.
First of all, thank you for making it.
I'd like to apply it to Zergling produced by Hatchery, so can you modify it a little?
I don't want to: "Zergling morped from larva is not a newly created unit."
I'm sorry.

[armoha]

@TAEKHi Just like zerglings collection in example, you can create larvas collection and loop larvas to detect morph. I could modify but it's a bit out of scope and I'd like to keep example short and concise.

Ask me later if you tried but didn't get how to do.

[armoha]

@TAEKHi Instead of making array of larvas, you can also loop selected units and see if it's larva and morphing into zergling. Similar to detecting train broodling button of zergling in #61 (comment) , you can detect morph zergling button of larva.

[TAEKHi]

@armoha Yes, I'll keep trying.
I don't want a free ride either, but I want to keep getting help.
How can I support you?