build.gradle

plugins {
    id "java"
    id "idea"
    id "com.github.johnrengelman.shadow" version "6.1.0"
    id "net.minecraftforge.gradle.forge"
    id "org.spongepowered.mixin"
}

repositories {
    mavenLocal()
    mavenCentral()
    maven { url = "https://repo.spongepowered.org/repository/maven-public/" }
    maven { url = "https://repo.spongepowered.org/maven/" }
    maven { url = "https://jitpack.io/" }
    flatDir { dir "libs" }
}

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

sourceCompatibility = targetCompatibility = 1.8
compileJava.options.encoding = "UTF-8"

minecraft {
    version = "1.8.9-11.15.1.2318-1.8.9"
    runDir = "run"
    mappings = "stable_22"
    makeObfSourceJar = false
    clientJvmArgs += ["-Dfml.coreMods.load=dev.phonis.schematica_extensions.mixins.MixinLoader", "-Xmx4096m", "-Xms1024m", "-Ddev-mode"]
}

configurations {
    include
    implementation.extendsFrom(include)
    runtimeOnly.canBeResolved = true
}

dependencies {
    deobfCompile group: "com.github.lunatrius", name: "LunatriusCore", version: "${project.version_minecraft}-${project.version_lunatriuscore}"
    deobfCompile group: "com.github.lunatrius", name: "Schematica", version: "${project.version_minecraft}-${project.version_schematica}"
    include("org.spongepowered:mixin:0.7.11-SNAPSHOT") {
        transitive = false
        exclude module: "guava"
        exclude module: "commons-io"
        exclude module: "gson"
        exclude module: "launchwrapper"
        exclude module: "log4j-core"
        exclude module: "slf4j-api"
    }
    annotationProcessor("org.spongepowered:mixin:0.7.11-SNAPSHOT")
}

shadowJar {
    archiveClassifier.set("")
    configurations = [project.configurations.include]
    duplicatesStrategy DuplicatesStrategy.EXCLUDE
    exclude "LICENSE.txt"
    exclude "META-INF/maven/**"
    exclude "META-INF/versions/**"
    exclude "org/apache/log4j/**"
    exclude "org/apache/commons/**"
    exclude "org/junit/**"
}

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version
    filesMatching("mcmod.info") {
        expand "version": project.version, "mcversion": project.minecraft.version
    }
    rename "(.+_at.cfg)", "META-INF/\$1"
}

task moveResources {
    doLast {
        copy {
            from "${buildDir}/resources/main"
            into "${buildDir}/classes/java"
        }
    }
}

moveResources.dependsOn(processResources)
classes.dependsOn(moveResources)

jar {
    manifest.attributes("FMLCorePlugin": "dev.phonis.schematica_extensions.mixins.MixinLoader",
            "FMLCorePluginContainsFMLMod": true,
            "ForceLoadAsMod": true,
            "MixinConfigs": "mixins.schematica_extensions.json",
            "ModSide": "CLIENT",
            "TweakClass": "org.spongepowered.asm.launch.MixinTweaker",
            "TweakOrder": "0",
            "FMLAT": "schematica_extensions_at.cfg")
    enabled = false
}

mixin {
    disableRefMapWarning = true
    defaultObfuscationEnv searge
    add sourceSets.main, "mixins.schematica_extensions.refmap.json"
}

reobf {
    shadowJar {
        mappingType = "SEARGE"
    }
}

jar.dependsOn("shadowJar")

tasks.reobfShadowJar.mustRunAfter shadowJar

task copyZipInclude(type: Copy) {
    from "zip_include/"
    into "build/libs/zip"
}

build.dependsOn copyZipInclude