build.gradle

buildscript {
    ext.kotlin_version = '1.1.2-2'
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply from: "utils.gradle"

apply plugin: "java"
apply plugin: "maven"
apply plugin: "kotlin"

group = 'org.fountainmc'
version = '0.1.0-alpha1-SNAPSHOT'

ext.versionSignature = rawComputeVersionSignature(version)

description = """FountainAPI"""

sourceCompatibility = 1.8
targetCompatibility = 1.8
tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

repositories {
    mavenCentral()
    maven { url "https://repo.techcable.net/content/groups/public/" }
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"
    compile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version" // Include kotlin reflection too ^_^
    compile "com.google.guava:guava:$guava_version"
    compile "com.google.code.gson:gson:$gson_version"
    // Use slf4j to abstract away the underlying logging framework and avoid the bukkit/bungee logging fiasco
    compile "org.slf4j:slf4j-api:$slf4j_version"
    testCompile 'junit:junit:4.12'
    testCompile 'org.hamcrest:hamcrest-junit:2.0.0.0'
    compileOnly 'com.google.code.findbugs:jsr305:1.3.9'
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}

jar {
    inputs.property("versionSignature", versionSignature) // Recompute manifest when signature changes
    manifest {
        attributes(
                "Specification-Title": "FountainAPI",
                "Specification-Version": versionSignature,
                "Specification-Vendor": "FountainMC Team",
        )
    }
}