publish-android.gradle

apply plugin: 'com.github.dcendents.android-maven'
apply plugin: 'signing'
//apply plugin: 'distribution'

nexusStaging {
    packageGroup = 'com.cyphercove.gdx'
    username = ossrhUsername
    password = ossrhPassword
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            if (isReleaseBuild()) {
                repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }
            }
            else {
                snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }
            }

            pom.project {
                name = projectName
                packaging 'aar'
                description = projectDesc
                url 'http://github.com/cyphercove/gdx-cclibs/'

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                scm {
                    connection 'scm:git:git@github.com:cyphercove/gdx-cclibs.git'
                    developerConnection 'scm:git:git@cyphercove/gdx-cclibs.git'
                    url 'http://github.com/cyphercove/gdx-cclibs/'
                }

                organization {
                    name 'Cypher Cove'
                    url 'www.cyphercove.com'
                }

                developers {
                    developer {
                        id 'cypherdare'
                        name 'Darren'
                        email 'contact@cyphercove.com'
                    }
                }

            }
        }
    }
}

signing {
    required { isReleaseBuild() && gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}


task androidJavadocs(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
    // JDK 1.8 is more strict then 1.7. Have JDK 1.8 behave like 1.7 for javadoc generation
    if (org.gradle.internal.jvm.Jvm.current().getJavaVersion() == JavaVersion.VERSION_1_8) {
        options.addStringOption('Xdoclint:none', '-quiet')
    }
}

task androidJavadocsJar(type: Jar, dependsOn: androidJavadocs) {
    classifier = 'javadoc'
    from androidJavadocs.destinationDir
}

task androidSourcesJar(type: Jar) {
    classifier = 'sources'
    from android.sourceSets.main.java.sourceFiles
}

artifacts {
    archives androidSourcesJar
    archives androidJavadocsJar
}

afterEvaluate {
    androidJavadocs.classpath += project.android.libraryVariants.toList().first().javaCompile.classpath
}