build.gradle

buildscript {
  repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
    jcenter()
  }
  dependencies {
    classpath 'com.android.tools.build:gradle:2.2.3'
    classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.5.3"
    classpath 'com.github.dcendents:android-maven-gradle-plugin:1.5'
  }
}

apply plugin: 'io.codearte.nexus-staging'

ext {
  GROUPID = 'com.cyphercove.gdx'
  LIBRARY_VERSION = '1.1.2-SNAPSHOT'
}

def isReleaseBuild() {
  return false
}

def getLibraryVersion() {
  if (isReleaseBuild()) {
    return LIBRARY_VERSION.replace("-SNAPSHOT", "")
  } else {
    return LIBRARY_VERSION;
  }
}

allprojects {
  apply plugin: 'eclipse'
  apply plugin: 'idea'

  ext {
    gdxVersion = '1.9.7'
    exp4jVersion = '0.4.8'
  }

  repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
    maven { url "https://oss.sonatype.org/content/repositories/releases/" }
  }

  group = GROUPID
  version = getLibraryVersion()
}

subprojects {
  eclipse.project.name = projectName
  project.group = rootProject.properties.GROUPID
}

configure([project(':covetools'), project(':flexbatch'), project(':gdxtokryo')])  {
  apply plugin: 'java'

  ext {
    wagonVersion = '2.10'
    junitVersion = '4.12'
  }

  dependencies {
    compile "com.badlogicgames.gdx:gdx:$gdxVersion"
    testCompile "junit:junit:$junitVersion"
  }

  sourceCompatibility = 1.7
  targetCompatibility = 1.7
}

project(':covetools-android') {
  apply plugin: 'com.android.library'

  dependencies {
    compile project(':covetools')
    compile "com.badlogicgames.gdx:gdx-backend-android:$gdxVersion"
  }
}

tasks.eclipse.doLast {
  delete ".project"
  delete ".classpath"
  delete ".settings/"
}